pulseIn() — это блокирующая функция: она ожидает, пока не получит полное пульса или до тех пор, пока не истечет время ожидания. Пока он ждет, Arduino не может что-нибудь еще, и он будет пропускать импульсы на других каналах.

Приемник RC посылает импульсы последовательно. Тогда, если вы попытаетесь прочитать их в правильной последовательности, это может сработать. Если вы прочитаете их из последовательность, вы пропустите несколько импульсов, и соответствующий pulseIn() вызовы могут истечь, возвращая нули.

Для такого рода задач я бы использовал прерывание смены контакта на контактах 2–7. Это должно позволить непрерывно считывать шесть импульсов без блокировки. вся программа. Но это низкоуровневое (AVR-уровня) программирование, наверное невозможно со стандартными библиотеками Arduino.

Правка. Вот что я имел в виду, когда предлагал использовать контакт. изменить прерывание. Обратите внимание, что номера контактов «зашиты» в код и не может быть легко изменен. Это потому что:

1. Выводы 2–7 совместно используют запрос прерывания на изменение одного контакта. (PCINT2_vect), поэтому для синхронизации шести каналов требуется один ISR.
2. Они также имеют общий порт (порт D), что означает, что все они могут быть прочитаны ISR в одной инструкции.

Другим возможным вариантом, обладающим этими замечательными свойствами, могут быть контакты. 8–13 (PCINT0_vect, порт B) или A0–A5 (PCINT1_vect, порт C).

/*
* Чтение 6 сигналов ШИМ с радиоуправляемого приемника.
*
* Каналы 0-5 подключены к цифровым контактам 2-7 (т.е. PD2-PD7 = PCINT18-23).
*/

// Всегда содержит последнюю длину, измеренную на каждом канале.
volatile uint16_t last_pulse_lengths[6];

// Прерывание срабатывает при каждом изменении контактов 2-7.
ISR(PCINT2_vect)
{
    static uint8_t last_pin_states;
    static uint16_t start_times[6];  // время начала для каждого канала
    uint8_t pin_states = PIND >> 2;  // смещено в биты 0-5
    uint16_t now = micros();

    // Проверяем каждый измененный бит порта.
    for (int i = 0; i < 6; i++) {
        uint8_t mask = _BV(i);

        // Время начала записи по переднему фронту.
        if ((pin_states & mask) && !(last_pin_states & mask))
            start_times[i] = now;

        // Запись длины импульса на заднем фронте.
        if (!(pin_states & mask) && (last_pin_states & mask))
            last_pulse_lengths[i] = now - start_times[i];
    }
    last_pin_states = pin_states;
}

// Возвращаем длину импульса, избегая условий гонки.
static void get_pulse_lengths(uint16_t lengths[6])
{
    for (int i = 0; i < 6; i++) {
        noInterrupts();
        uint16_t tmp = last_pulse_lengths[i];
        interrupts();
        lengths[i] = tmp;
    }
}

void setup()
{
    // Настройка прерывания смены контакта.
    PCIFR  = _BV(PCIF2);  // сброс флага прерывания смены контакта
    PCICR  = _BV(PCIE2);  // разрешить прерывание смены контакта
    PCMSK2 = 0xfc;        // воспринимать изменения на контактах 2-7 (т.е. PD2-PD7)

    Serial.begin(9600);
}

void loop()
{
    // Сообщить длину импульса на последовательной консоли.
    uint16_t pulse_lengths[6];
    get_pulse_lengths(pulse_lengths);
    for (int i = 0; i < 6; i++) {
        Serial.print(pulse_lengths[i]);
        if (i < 5) Serial.print(", ");
        else Serial.println();
    }

    delay(1000);
}