Arduino: считывание частоты входного сигнала с аудиоразъема

Вы можете измерить одну "чистую" частоту, подсчитав количество раз, когда штифт меняется, используя встроенные таймеры. Вот эскиз с моей страницы о таймерах, который выполняет это:

// Пример таймера и счетчика
// Автор: Ник Гэммон
// Дата: 17 января 2012 г.

// Вход: контакт D5

// они проверяются в основной программе
volatile unsigned long timerCounts;
volatile boolean counterReady;

// внутренний для подсчета процедуры
unsigned long overflowCount;
unsigned int timerTicks;
unsigned int timerPeriod;

void startCounting (unsigned int ms) 
  {
  counterReady = false;         // время еще не вышло
  timerPeriod = ms;             // сколько отсчетов по 1 мс нужно сделать
  timerTicks = 0;               // сбросить счетчик прерываний
  overflowCount = 0;            // переполнения пока нет

  // сбросить Таймер 1 и Таймер 2
  TCCR1A = 0;             
  TCCR1B = 0;              
  TCCR2A = 0;
  TCCR2B = 0;

  // Таймер 1 - подсчитывает события на выводе D5
  TIMSK1 = bit (TOIE1);   // прерывание по переполнению таймера 1

  // Таймер 2 - дает нам интервал подсчета в 1 мс
  // Тактовая частота 16 МГц (62,5 нс на тик) - предварительно масштабировано на 128
  // счетчик увеличивается каждые 8 мкс.
  // Итак, мы насчитали 125 из них, что дает ровно 1000 мкс (1 мс)
  TCCR2A = bit (WGM21) ;   // Режим CTC
  OCR2A  = 124;            // считаем до 125 (относительно нуля!!!!)

  // Таймер 2 - прерывание при совпадении (т.е. каждую 1 мс)
  TIMSK2 = bit (OCIE2A);   // включить прерывание Таймера 2

  TCNT1 = 0;      // Оба счетчика равны нулю
  TCNT2 = 0;     

  // Сброс предделителей
  GTCCR = bit (PSRASY);        // сбросить предварительный делитель сейчас
  // запустить Таймер 2
  TCCR2B =  bit (CS20) | bit (CS22) ;  // предделитель 128
  // запустить Таймер 1
  // Внешний источник синхронизации на выводе T1 (D5). Синхронизация по нарастающему фронту.
  TCCR1B =  bit (CS10) | bit (CS11) | bit (CS12);
  }  // конец начала подсчета

ISR (TIMER1_OVF_vect)
  {
  ++overflowCount;               // подсчитываем количество переполнений Counter1
  }  // конец TIMER1_OVF_vect


//***************************************************************************
// Служба прерывания Таймера2 вызывается аппаратным Таймером 2 каждую 1 мс = 1000 Гц
// 16МГц / 128 / 125 = 1000 Гц

ISR (TIMER2_COMPA_vect) 
  {
  // захватываем значение счетчика до того, как оно изменится
  unsigned int timer1CounterValue;
  timer1CounterValue = TCNT1;  // см. техническое описание, стр. 117 (доступ к 16-битным регистрам)
  unsigned long overflowCopy = overflowCount;

  // смотрим, достигли ли мы временного периода
  if (++timerTicks < timerPeriod) 
    return;  // пока нет

  // если просто пропустил переполнение
  if ((TIFR1 & bit (TOV1)) && timer1CounterValue < 256)
    overflowCopy++;

  // окончание времени ворот, измерение готово

  TCCR1A = 0;    // остановить таймер 1
  TCCR1B = 0;    

  TCCR2A = 0;    // остановить таймер 2
  TCCR2B = 0;    

  TIMSK1 = 0;    // отключить прерывание Таймера 1
  TIMSK2 = 0;    // отключить прерывание Timer2

  // подсчитать общее количество
  timerCounts = (overflowCopy << 16) + timer1CounterValue;  // каждое переполнение на 65536 больше
  counterReady = true;              // установить глобальный флаг для окончания периода подсчета
  }  // конец TIMER2_COMPA_vect

void setup () 
  {
  Serial.begin(115200);       
  Serial.println("Frequency Counter");
  } // конец настройки

void loop () 
  {
  // остановить прерывания таймера 0 от сброса отсчета
  byte oldTCCR0A = TCCR0A;
  byte oldTCCR0B = TCCR0B;
  TCCR0A = 0;    // остановить таймер 0
  TCCR0B = 0;    

  startCounting (500);  // сколько мс нужно посчитать

  while (!counterReady) 
     { }  // цикл, пока не закончится

  // отрегулируйте счетчики, установив интервал подсчета, чтобы получить частоту в Гц
  float frq = (timerCounts *  1000.0) / timerPeriod;

  Serial.print ("Frequency: ");
  Serial.print ((unsigned long) frq);
  Serial.println (" Hz.");

  // перезапустить таймер 0
  TCCR0A = oldTCCR0A;
  TCCR0B = oldTCCR0B;

  // пусть серийные вещи закончатся
  delay(200);
  }   // конец цикла

Подавая синусоиду частотой 1 кГц (от 0 В до 5 В), я получаю следующий результат:

Frequency Counter
Frequency: 1000 Hz.
Frequency: 1002 Hz.
Frequency: 1000 Hz.
Frequency: 1000 Hz.
Frequency: 1000 Hz.
Frequency: 1000 Hz.
Frequency: 1002 Hz.
Frequency: 1000 Hz.
Frequency: 1000 Hz.
Frequency: 1000 Hz.

Иногда бывают неточности, но выглядит достаточно точно. Вы можете сделать выборку несколько раз, и если вы получите что-то между 990 и 1010 пять раз, вы можете считать это совпадением.

Вам нужно убедиться, что входной сигнал находится в диапазоне для срабатывания входной схемы Arduino. Он должен быть около 4–5 В и не должен превышать 5 В (для высокого уровня). Он также не должен быть отрицательным.

Что-то вроде этого защитит входной контакт:

Предупреждение - звук из аудиоразъема будет переменным и станет отрицательным. Убедитесь, что вы используете подходящую защиту входа.

Усиление

Посмотрев Википедия - Уровень линии, можно предположить, что выходной сигнал вашего телефона будет недостаточно высоким (вероятно, около 700 мВ). Поэтому, вероятно, потребуется простой транзисторный усилитель, чтобы поднять его до уровня, который можно будет обнаружить.

Вдохновленный этим постом на Electronics Stack Exchange, я сконструировал простой усилитель:

Тестирование с пиковым входным сигналом около 500 мВ показало, что он успешно усилил его до 0–5 В постоянного тока:

Альтернативный метод с аналоговым компаратором

Основываясь на предложениях Криса Стрэттона, есть другой способ сделать это.

Вы можете использовать аналоговый компаратор для обнаружения аналогового сигнала, проходящего пороговое значение, например:

Я настроил делитель напряжения на срабатывание при 0,265 В, так что сигнал 500 мВ должен обеспечить приемлемый диапазон срабатывания.

Что касается эскиза, то на этих частотах мы можем сделать что-то проще, чем то, что я выкладывал ранее:

volatile bool counting;
volatile unsigned long count;

ISR (ANALOG_COMP_vect)
  {
  if (counting)
    count++;
  }

void setup ()
  {
  Serial.begin (115200);
  Serial.println ("Started.");
  ADCSRB = 0;           // (Отключить) ACME: Включение аналогового компаратора-мультиплексора
  ACSR =  bit (ACI)     // (Очистить) Флаг прерывания аналогового компаратора
        | bit (ACIE)    // Разрешение прерывания аналогового компаратора
        | bit (ACIS1);  // ACIS1, ACIS0: Выбор режима прерывания аналогового компаратора (запуск по заднему фронту)
   }  // конец настройки

unsigned long startTime;

void loop ()
  {

  if (!counting)
    {
    startTime = micros ();
    count = 0;
    counting = true;
    }
  else
    {
    // прошла ли секунда? (1000000 микросекунд)
    if (micros () - startTime >= 1000000)
      {
      counting = false;
      Serial.print (count);
      Serial.println (F(" Hz."));
      }  // конец секунды вверх

    }  // конец if

  }  // конец цикла