Объяснение кода MPU6050

Я новичок в Arduino и электронике. Я пытался использовать MPU6050 с моим Arduino, но мне трудно понять код. Я имею в виду код, размещенный на веб-сайте Arduino (http://playground.arduino.cc/Main/ MPU-6050#короткий). Можно ли как-нибудь получить построчное объяснение кода?

, 👍1

Обсуждение

.... связь? ...., @Majenko

http://playground.arduino.cc/Main/MPU-6050#short, @Shubham Jha

все мои значения всегда равны нулю, какую ошибку я могу совершить?, @Alejandra Gutierrez


1 ответ

Лучший ответ:

2

Я добавил для вас несколько комментариев:

// Краткий пример скетча MPU-6050
// Пользователь Arduino JohnChi
// 17 августа 2014 г.
// Всеобщее достояние
#include<Wire.h>
const int MPU_addr=0x68;  // I2C-адрес MPU-6050
int16_t AcX,AcY,AcZ,Tmp,GyX,GyY,GyZ; // объявляем переменные акселерометра и гироскопа
void setup(){
  Wire.begin(); // инициируем систему i2c
  Wire.beginTransmission(MPU_addr); // убедитесь, что мы говорим с нашим MPU, а не с каким-то другим устройством
  Wire.write(0x6B);  // регистр PWR_MGMT_1
  Wire.write(0);     // устанавливаем на ноль (пробуждает MPU-6050)
  Wire.endTransmission(true); // на данный момент закончен разговор с устройством MPU
  Serial.begin(9600); // инициализируем последовательный порт на скорости 9600 бит/с, чтобы вы могли видеть свои отладочные сообщения в Arduino IDE через канал отладки
}
void loop(){ // цикл основной программы
  Wire.beginTransmission(MPU_addr); // готовимся снова поговорить с MPU
  Wire.write(0x3B);  // начиная с регистра 0x3B (ACCEL_XOUT_H)
  Wire.endTransmission(false); // на данный момент разговор с MPU закончен
  Wire.requestFrom(MPU_addr,14,true);  // запрашиваем всего 14 регистров
  // все самое интересное <<8| суть в том, чтобы сдвинуть первые 8 бит на
  // левый & объедините его со следующими 8 битами, чтобы сформировать 16 бит
  AcX=Wire.read()<<8|Wire.read();  // 0x3B (ACCEL_XOUT_H) & 0x3C (ACCEL_XOUT_L)
  AcY=Wire.read()<<8|Wire.read();  // 0x3D (ACCEL_YOUT_H) & 0x3E (ACCEL_YOUT_L)
  AcZ=Wire.read()<<8|Wire.read();  // 0x3F (ACCEL_ZOUT_H) & 0x40 (ACCEL_ZOUT_L)
  Tmp=Wire.read()<<8|Wire.read();  // 0x41 (TEMP_OUT_H) & 0x42 (TEMP_OUT_L)
  GyX=Wire.read()<<8|Wire.read();  // 0x43 (GYRO_XOUT_H) & 0x44 (ГИРО_XOUT_L)
  GyY=Wire.read()<<8|Wire.read();  // 0x45 (GYRO_YOUT_H) & 0x46 (GYRO_YOUT_L)
  GyZ=Wire.read()<<8|Wire.read();  // 0x47 (GYRO_ZOUT_H) & 0x48 (ГИРО_ZOUT_L)
  // строки выше собрали значения акселерометра для X, Y, Z
  // а также значения гироскопа для X, Y, Z

  Serial.print("AcX = "); Serial.print(AcX); // передаем значения акселерометра по каналу отладки
  Serial.print(" | AcY = "); Serial.print(AcY);
  Serial.print(" | AcZ = "); Serial.print(AcZ);
  Serial.print(" | Tmp = "); Serial.print(Tmp/340.00+36.53);  //уравнение температуры в градусах Цельсия из таблицы данных
  Serial.print(" | GyX = "); Serial.print(GyX); // передаем значения гироскопа по каналу отладки
  Serial.print(" | GyY = "); Serial.print(GyY);
  Serial.print(" | GyZ = "); Serial.println(GyZ);
  delay(333); // немного задержимся, чтобы не перегружать пользователя/программиста просмотром результатов
}
,

Конечно! Если этот ответ вас устраивает, не забудьте поставить галочку «ответил» =), @Malachi

Смотрите также: