Несколько операторов If

#include <LiquidCrystal.h>
#include <GSM.h>

GSM gsmAccess;
GSM_SMS sms;
char sendernumber[20]; 
int Enable_m=11;
int Control_2=12;
int Control_7=10;
LiquidCrystal lcd(7,8,9,8,1,2,3,4,5,6);

void setup() 
{
   Serial.begin(9600);
   pinMode(Enable_m,OUTPUT);
   pinMode(Control_2,OUTPUT);
   pinMode(Control_7,OUTPUT);

   digitalWrite(Enable_m,LOW);
   digitalWrite(Control_2,LOW);
   digitalWrite(Control_7,LOW);

   lcd.begin(16,2);
   lcd.clear();
   lcd.setCursor(0,0);
   lcd.print("Hello");
   lcd.setCursor(0,1);
   lcd.print("Everyone");
   delay(2000);

   while (!Serial) 
      Serial.println("SMS Messages Receiver");
   boolean notConnected = true;
   while(notConnected)
   {
      if(gsmAccess.begin("0000")==GSM_READY)
         notConnected = false;
      else
      {
         Serial.println("Not connected");
         delay(1000);
      }
   }  
   Serial.println("GSM initialized");
   Serial.println("Waiting for messages");
}

void loop() {
   // put your main code here, to run repeatedly:

   // I chose 160 since that is max size for sms
   char message [160]; 
   // this fills message with null characters
   memset( message, '\0', sizeof(char)*160 ); 

   int val=0;
   val=digitalRead(Enable_m);
   if (val==LOW){
      digitalWrite(Enable_m,HIGH);
   }
   if (sms.available())
   {
      Serial.println("Message received from:");
      sms.remoteNumber(sendernumber, 20);
      Serial.println(sendernumber);

      // you used single qoutes properly here
      // single qoutes denote a char which is a single character
      if(sms.peek()=='#')
      {
         Serial.println("Discarded SMS");
         sms.flush();
      }


      // this will add the characters to messages[]
      for(int i = 0; message[i] = sms.read(); i++){}

      // I changed this to double qoutes since you need double
      // qoutes to denote a string literal
      if(strcmp(message, "motoroff") == 0){
         analogWrite(Enable_m, 0);
         digitalWrite(Control_2,LOW);
         digitalWrite(Control_7,LOW);
      }
      else if(strcmp(message, "motoronclockwise") == 0){
         analogWrite(Enable_m, 255);
         digitalWrite(Control_2,LOW);
         digitalWrite(Control_7,HIGH);
      }
      else if(strcmp(message, "motoronanticlockwise") == 0){
         analogWrite(Enable_m, 255);
         digitalWrite(Control_2,HIGH);
         digitalWrite(Control_7,LOW);
      }
      else if(strcmp(message, "speedhalf") == 0){
         analogWrite(Enable_m, 128);
         digitalWrite(Control_2,LOW);
         digitalWrite(Control_7,HIGH);
      }
      else if(strcmp(message, "speedquarter") == 0){
         analogWrite(Enable_m, 65);
         digitalWrite(Control_2,LOW);
         digitalWrite(Control_7,HIGH);
      }
      else if(strcmp(message, "speed75") == 0){
         analogWrite(Enable_m, 192);
         digitalWrite(Control_2,LOW);
         digitalWrite(Control_7,HIGH);
      }
      // This else will only be executed if the previous if and else if statements are false
      else{
         digitalWrite(Enable_m,HIGH);
         Serial.print(message);
      }
      Serial.println("\nEND OF MESSAGE");
      sms.flush();
      Serial.println("MESSAGE DELETED");
   }

}

Итак, я внес некоторые изменения в ваш код. Например, этот код 'motoronanticlock' неверен. Одинарные кавычки используются для типов данных char, а двойные кавычки используются для строковых литералов. Вам следует использовать двойные кавычки, поскольку есть несколько символов "motoronanticlock". Также, как сказал Маженко, вам придется использовать strcmp() для сравнения c-строок c-строки — это массивы char, которые имеют нулевой терминатор '\0'. Также strcmp() возвращает 0, если две строки равны.

Ваш последний оператор else будет выполнен только в том случае, если предыдущий оператор if будет false. Похоже, вы хотите, чтобы он выполнялся только в том случае, если все предыдущие операторы if будут ложными. Для этого вы создаете первый оператор if, а затем создаете цепочку операторов if else, за которыми следует один оператор else. Вы можете иметь один оператор if без операторов else или if else, однако, если вы хотите операторы else или if else, вам нужно иметь оператор if. Я уже внес необходимые изменения в ваш код.

Наконец, эта часть программы является самой большой проблемой while(c=sms.read()) Это потому, что sms.read() возвращает char, поэтому вы можете читать sms-сообщение только по одному символу за раз. Чтобы сделать это правильно, вам следует создать массив символов и сохранить в нем значения, возвращаемые sms.read(). Это можно сделать так

char message [160]; // Я выбрал 160, так как это максимальный размер для смс
memset( message, '\0', sizeof(char)*160 ); // это заполняет сообщение нулевыми символами
// это добавит символы в messages[]
for(int i = 0; message[i] = sms.read(); i++){}

Я использую цикл for для перебора message[].

Попробуйте сделать все вышеперечисленное и свяжитесь со мной, если возникнут какие-либо проблемы.