Код для циклического загрузчика, похоже, завис

Я пытаюсь создать циклер зарядки аккумулятора, который будет заряжать и разряжать аккумулятор многократно в течение определенного количества циклов. Вот мой код:

bool in_charge_mode;
int cycles = 0;
float cutoffvoltage = 2.0f;

float get_batt_voltage() {
    return analogRead(A1) * 5.0f / 1023.0f;
}

void set_charge_mode() {
    in_charge_mode = true; // запомнить состояние
    digitalWrite(13, HIGH); //начать зарядку
    digitalWrite(12, LOW); //прекращаем разрядку для загрузки
}

void set_discharge_mode() {
    in_charge_mode = false;
    digitalWrite(13, LOW); //остановить зарядку
    digitalWrite(12, HIGH); //разряд для загрузки
}

void setup() {
    Serial.begin(9600);
    pinMode(12, OUTPUT); //Подключено к реле 1, которое является реле нагрузки
    pinMode(13, OUTPUT); //Подключено к реле 2, которое является реле для зарядного устройства
    // Проверить начальное напряжение
    float vbat = get_batt_voltage();
    if (vbat < cutoffvoltage) {
        // напряжение батареи ниже порогового, нужно начать зарядку
        set_charge_mode();
    } else {
        // мы можем разрядить, если напряжение выше порогового
        set_discharge_mode();
    }
}

void loop() {
    if (cycles >= 500) {
        Serial.println("Refusing to do anything, number of cycles too high");
        set_charge_mode(); // для отключения от нагрузки или чего-то еще
        return;
    }

    float vbat = get_batt_voltage();
    Serial.println("Battery voltage: " + String(vbat) + " is charging: " + String(in_charge_mode));
    if (in_charge_mode) {
        if (vbat > 4.2f) {
            // мы закончили зарядку! увеличиваем счетчик циклов
            cycles++; // технически это количество «завершенных зарядок»
            Serial.println("BATTERY CHARGED SUFFICIENTLY. Discharging again.");
            set_discharge_mode();
        } else {
            Serial.println("Still charging up the battery, waiting..");
        }
    } else {
        // в режиме разряда
        if (vbat < cutoffvoltage) {
            // напряжение батареи упало ниже порогового значения, нам нужно снова зарядить ее
            Serial.println("BATTERY DISCHARGED. Charging up again.");
            set_charge_mode();
        } else {
            Serial.println("Still dicharging the battery, waiting..");
        }
    }
    delay(1000); // проверка снова через секунду
}

Однако последовательный монитор продолжает повторять это:

Battery voltage: 4.18 is charging: 0
Still dicharging the battery, waiting..
Battery voltage: 4.18 is charging: 0
Still dicharging the battery, waiting..
Battery voltage: 4.18 is charging: 0

Похоже, он пытается разрядить аккумулятор, но продолжает заряжаться? Я ждал около часа, и напряжение остаётся на уровне 4,18 В, иногда показывает 4,17 В, но потом снова падает до 4,18 В.

Что может быть не так? Спасибо.

РЕДАКТИРОВАНИЕ: вот фотография моей схемы