Я не уверен, что перенос длительной задачи в noInterrupts()/interrupts() — это правильный выбор...

Правильно. Отключение прерываний приведет к прекращению работы таймера/задержки, поэтому вы не сможете рассчитать время 200 мкс (если вы не используете задержкумикросекунды).

Каждое воздействие длится всего пару сотен микросекунд, поэтому даже периодическое дрожание в 2,625 мкс увеличит время воздействия как минимум на 1%.

Я думаю, вам лучше использовать аппаратный таймер для расчета времени экспозиции, а не цикл. Я сгенерировал сигналы VGA в сообщении здесь, где я хотел, чтобы горизонтальная и вертикальная синхронизация не имели никакого дрожания. Таймеры можно настроить на включение или выключение выходного контакта, чтобы его можно было использовать для управления затвором. Тогда это было бы совершенно точно.

Я не знал, что UART прерывает работу процессора...

Входящие (или даже исходящие) последовательные соединения вызывают прерывания. Таймеры вызывают прерывания. В частности, если вы не отключили его, Таймер 0 генерирует прерывания, которые учитываются, чтобы функции millis() и micros() могли работать. Вы можете отключить прерывания, но тогда определение точного времени интервалов станет проблематичным. Мое предложение использовать аппаратное обеспечение таймера обеспечит наиболее надежную и повторяемую работу, точно так же, как мое генерирование сигнала VGA было полностью без джиттера.

Из-за прерываний по таймеру, если вы не отключили прерывания, у некоторых ваших экспозиций прерывание по таймеру может быть посередине (что делает их длиннее), а у некоторых нет или, по крайней мере, будет другое количество прерываний. Это сделает время экспозиции неточным.

Другой подход — отключить прерывания только для воздействия (т. е. ваши 200 мкс, а не упомянутые вами 400 мс), а затем использовать задержкуМикросекунды() для определения времени воздействия. Затем, когда прерывания снова активируются, замыкание переключателя (внешнее прерывание) может быть обработано обычным ISR. Это может добавить небольшие различия во времени между воздействиями, но само время воздействия будет постоянным.

Даже при отключенных прерываниях внешнее прерывание «запоминается». и будет обработан, когда прерывания снова будут включены.

Это превращается в проблему XY. Было бы лучше упомянуть ваши точные требования (часть фотографии), а не задаваться вопросами об использовании прерываний в качестве задержек.

Пример кода

Чтобы продемонстрировать, как это можно сделать с помощью таймеров, я написал пример кода:

// Пример стробирования вспышки FRAMES_TO_TAKE раз для съемки
// Время между каждой вспышкой составляет TIME_BETWEEN_SEQUENCES
// Вспышка "включена" время через STROBE_ON_TIME
//
// Для Atmega328P (Arduino Uno и аналогичные)
// и Atmega2560 (Arduino Mega)

// Автор: Ник Гаммон
// Дата: 4 июля 2023 г.

const byte FRAMES_TO_TAKE = 12;
const byte CPU_CLOCK_SPEED = 16;  // МГц

const unsigned long TIME_BETWEEN_SEQUENCES = 20000;  // мкс
const unsigned long STROBE_ON_TIME = 200;  // мкс
const byte PRESCALER = 64;

// устанавливаем правильный выходной контакт
#if defined(__AVR_ATmega168__) || defined(__AVR_ATmega328P__)
  const byte FLASH_PIN = 10;  // OC1B (Таймер сравнения выходов 1: сторона B) — Atmega328P
#elif defined(__AVR_ATmega1280__) || defined(__AVR_ATmega2560__)
  const byte FLASH_PIN = 12;  // OC1B (Таймер сравнения выходов 1: сторона B) — Atmeg12560
#else
  #error Processor not supported
#endif

volatile byte count;  // сколько раз он выстрелил

// Таймер 1. Сравнение "B" вектор ISR
// подсчитаем необходимое количество экспозиций, затем остановимся
ISR (TIMER1_COMPB_vect)
  {
  if (++count > FRAMES_TO_TAKE)
    {
    // остановка таймера 1
    TCCR1A = 0;
    TCCR1B = 0;
    } // заканчиваем, если достигнуто количество кадров
    
  }  // конец TIMER1_COMPB_vect

// делает одну последовательность кадров FRAMES_TO_TAKE, а затем останавливается
void startSequence ()
{
  // остановка таймера 1
  TCCR1A = 0;
  TCCR1B = 0;

  TCCR1A = bit (WGM10) | bit (WGM11);  // быстрый ШИМ — верх на OCR1A
  TCCR1B = bit (WGM12) | bit (WGM13);  // (режим 15)

  TCCR1A |= bit (COM1B1);   // Установка OC1B во время рабочего цикла
  
  OCR1A = ((TIME_BETWEEN_SEQUENCES * CPU_CLOCK_SPEED) / PRESCALER) - 1;  // общее время цикла
  OCR1B = ((STROBE_ON_TIME * CPU_CLOCK_SPEED) / PRESCALER) - 1;          // время рабочего цикла
  count = 0;

  TCNT1 = 0;    // сброс счетчика таймера
  
  TIFR1   = bit (OCF1B);    // очищаем "сравнить B" флаг
  TIMSK1  = bit (OCIE1B);   // прерывание при сравнении совпадения B
  TCCR1B |= bit (CS10) | bit (CS11);     // запускаем таймер с прескалером 64
} // конец startSequence

void setup ()
  {
  // остановка таймера 1
  TCCR1A = 0;
  TCCR1B = 0;

  // устанавливаем пин, чтобы мы могли его переключать
  pinMode (FLASH_PIN, OUTPUT);
  digitalWrite (FLASH_PIN, LOW);

  // для отладки и т. д.
  Serial.begin (115200);
  }  // конец настройки

void loop ()
  {
  startSequence ();
  delay (20);
  Serial.print ("But does it get goat's blood out?\n");
  delay (1000);
   }  // конец цикла;

Пояснение кода

Этот код использует Таймер 1 для определения времени необходимых вам интервалов. На основании того, что вы опубликовали ранее, я предположил:

• 12 показов за «сеанс»; (FRAMES_TO_TAKE) – вы сказали «дюжина или около того»;
• Воздействие должно быть с интервалом 20 мс (TIME_BETWEEN_SEQUENCES), поэтому длительность сеанса составляет 240 мс.
• Время экспозиции должно составлять 200 мкс (STROBE_ON_TIME) — вы сказали «пару сотен микросекунд»;
• Вы хотите заняться другими делами, например последовательной связью, проверкой переключателей и т. д.

Функция startSequence запускает таймер с периодом 20 мс и рабочим циклом 200 мкс. По завершении рабочего цикла вызывается ISR, который подсчитывает рабочие циклы. По окончании названного числа (12) таймер выключается.

Выходной контакт (контакт 12 на Mega, контакт 10 на Uno) включен во время рабочего цикла (т. е. на 200 мкс и выключен в остальное время). Поскольку это реализовано аппаратно, джиттера вообще нет. В своей демонстрации я использую последовательную связь, чтобы показать, что интервалы правильные, несмотря на прерывания, вызванные связью.

Вывод логического анализатора

Скриншот логического анализатора показывает, что интервалы абсолютно правильные (с точностью до долей процента). В любом случае интервалы согласуются друг с другом.

На втором снимке экрана показано, что в этом интервале 12 импульсов.

Я использовал прескалер 64, чтобы получить хороший длинный интервал, который можно рассчитать по времени (без переполнения 16-битного размера счетчика). Это дает степень детализации 64 тактовых цикла (4 мкс).

Шпаргалка по таймеру 1