Как вывести ESP8266 из глубокого сна в определенную дату и время?

Поскольку ESP8266 не имеет настоящего встроенного RTC (т. е. он не способен сохранять очень точное время в глубоком сне) и ограничен коротким периодом времени одним из решений является использование внешнего RTC (часы реального времени). Ниже приведены два подхода, оба из которых включают DS3231 RTC (довольно легко получить в виде модуля).

«DS3231 — это недорогие, чрезвычайно точные часы реального времени I2C (RTC)». DS3231 "поддерживает точность RTC в пределах ±2 минуты в год в диапазоне от -40°C до +85°C"

Решение 1. Периодически активируйте MCU и проверяйте внешний RTC

Возможно, наиболее энергоэффективным решением (по сравнению с решением для будильника ниже) будет периодический вывод ESP8266 из режима глубокого сна для проверки времени на внешнем RTC и, в зависимости от желаемой точности, переход в режим глубокого сна на более короткие периоды по мере того, как вы приближайтесь к целевому времени пробуждения (например, просыпайтесь и проверяйте RTC каждую минуту, когда вы находитесь примерно в 10 минутах от целевого времени).

Чтобы сэкономить электроэнергию, перед тем как перевести ESP8266 в спящий режим, вы можете просто использовать транзистор, подключенный к GPIO, чтобы отключить источник питания Vcc на модуле DS3231 (он будет использовать встроенную батарею 2032, пока питание не подается).

При перезапуске с выключенным Wi-Fi (ESP.deepSleep(1e6, WAKE_RF_DISABLED)) ESP8266 нужно пробудить только примерно на 200 мс, потребляя 20 мА, чтобы проверить DS3231, пришло ли время полностью проснуться. . Это, вероятно, самый энергоэффективный вариант, который вы можете получить, если хотите сохранять точное время.

Решение 2. Установите будильник на внешнем RTC, чтобы разбудить MCU

При использовании DS3231 вывод SQW можно подключить к выводу RST ESP8266 через моностабильную схему. Моностабильная схема важна, потому что вывод RST не может оставаться на низком уровне, иначе он не загрузится. Моностабильная схема создает импульс на выводе RST, когда вывод SQW DS3231 становится низким.

Примечание о энергопотреблении: ESP8266 должен потреблять всего 20 мкА в режиме глубокого сна, но модули DS3231 обычно потребляют около 1 мА при включении (что требуется для срабатывания сигнализации). возможно из-за EEPROM на модуле. Это энергопотребление имеет большое значение, если вы разрабатываете систему с низким энергопотреблением. Вот почему это второе решение менее энергоэффективно по сравнению с первым решением.

Следующий код устанавливает будильник на определенное время, и когда на выводе RST устанавливается низкий уровень (на основе вывода SQW DS3231), ESP8266 просыпается. Убедитесь, что вы раскомментировали SLEEP_DT и установили дату и время для пробуждения в определенную дату и время (конечно, вы можете установить это программно на любую дату и время), иначе он будет просыпаться каждые n секунд (значение SLEEP_SECONDS), но это также может быть полезно (время глубокого сна ESP8266 не очень точное).

#include <ESP8266WiFi.h>
#include <WiFiUdp.h>
#include <NTPClient.h>
#include <RTClib.h>

#define WIFI_SSID "Your WiFi SSID"
#define WIFI_PASS "Your WiFi password"

// раскомментируйте, чтобы проснуться в определенную дату и время
//#определить SLEEP_DT
#define SLEEP_DT_YEAR 2022
#define SLEEP_DT_MONTH 12
#define SLEEP_DT_DAY 02
#define SLEEP_DT_HOUR 15
#define SLEEP_DT_MINUTE 50
#define SLEEP_DT_SECOND 25

#define SLEEP_SECONDS 10 // проще для тестирования

RTC_DS3231 rtc;
WiFiUDP udp;
NTPClient ntp(udp);

void print_date(const DateTime& dt);

void setup() {
  Serial.begin(9600);
  while (!Serial) { delay(1); }
  
  Serial.println('\n');
  Serial.println("Hello RTC wake deep sleep");
  
  Serial.println("Init DS3231");
  if(!rtc.begin()) {
    Serial.println("DS3231 failed");
    while (true) { delay(1); }
  }

  // не требуется
  rtc.disable32K();

  // не используется
  rtc.disableAlarm(2);

  // по-видимому, может привести к проблемам, если не очистить
  rtc.clearAlarm(1);
  rtc.clearAlarm(2);

  // прекращаем колебания; позволяет будильнику работать
  rtc.writeSqwPinMode(DS3231_OFF);
  
  Serial.println("Init WiFi");
  WiFi.begin(WIFI_SSID, WIFI_PASS);
  
  Serial.println("Connecting to " WIFI_SSID);
  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
  }
  Serial.print("Connected, IP: ");
  Serial.println(WiFi.localIP());
  
  ntp.begin();
  bool ntpOk = ntp.update();

  if (rtc.lostPower()) {
    Serial.println("RTC lost power, setting time");
    if (ntpOk) {
      Serial.println("Using time from NTP client");
      rtc.adjust(DateTime(ntp.getEpochTime()));
    }
    else {
      // непроверенный код
      Serial.println("NTP unavailable, using time of build");
      rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));
    }
  }
  
  Serial.print("Date and time set to: ");
  print_datetime(rtc.now());

#ifdef SLEEP_DT

  DateTime alarm(
    SLEEP_DT_YEAR,
    SLEEP_DT_MONTH,
    SLEEP_DT_DAY,
    SLEEP_DT_HOUR,
    SLEEP_DT_MINUTE,
    SLEEP_DT_SECOND);

  Serial.print("Setting alarm for date: ");
  print_datetime(alarm);
    
  if (!rtc.setAlarm1(alarm, DS3231_A1_Date)) {
    Serial.println("Failed to set alarm");
  }

#else

  // спать в течение заданных секунд в целях тестирования
  Serial.print("Setting alarm for seconds: ");
  Serial.print(SLEEP_SECONDS);
  Serial.println(" seconds");
  if (!rtc.setAlarm1(rtc.now() + TimeSpan(SLEEP_SECONDS), DS3231_A1_Second)) {
    Serial.println("Failed to set alarm");
  }
  
#endif // SLEEP_DT

  Serial.println("Going into deep sleep (wake on RST low)");
  Serial.flush();
  ESP.deepSleep(0);
}

void print_datetime(const DateTime& dt) {
  char df[] = "YYYY-MM-DD hh:mm:ss";
  Serial.println(dt.toString(df));
}

void loop() { }

Вот оно в действии...

Примечание. Время скачет, потому что я вырезал несколько кадров, чтобы вы не скучали (обещаю, никакого дыма и зеркал).