Неблокирующий скетч

Для такого рода вещей я был бы склонен создать массив (возможно, структур), описывающий, что вы хотите, чтобы реле делали, а затем написать программу, которая проходит через этот массив, выполняя каждую "инструкцию" в последовательности. Таким образом, он отделяет то, что вы хотите сделать, от того, как вы хотите, чтобы это было сделано (если это имеет смысл).

Итак, вы можете создать простую структуру:

typedef struct {
    uint8_t relays;
    uint32_t postDelay;
} RelayState;

Затем вы можете создать массив, используя эту структуру для описания ваших состояний реле. Использование растрового изображения для ваших реле (бит 0 — это реле 1, бит 1 — это реле 2 и т. д.) означает, что вы можете упаковать все в одно целое число и описать реле в двоичной записи:

RelayState states[] = {
    { 0b01000000,  3000 }, // Реле 7 включено, подождите 3 секунды
    { 0b11000000, 10000 }, // Реле 8 включено, подождите 10 секунд
    { 0b11100000, 10000 }, // Реле 6 включено, подождите 10 секунд
    { 0b10100000, 10000 }, // Реле 7 выключено, подождите 10 секунд
    { 0b10110000,  3000 }, // Реле 5 включено, подождите 3 секунды
    // ... так далее ...
    { 0, 0 } // Маркер конца массива
};

Если вы когда-нибудь захотите изменить последовательность, вы просто измените содержимое этого массива без необходимости связываться с остальной частью вашей программы.

Также может быть полезно создать массив контактов реле:

const uint8_t relayPins[8] = { 9, 8, 7, 6, 5, 4, 3, 2 };

Теперь вам просто нужно написать небольшую программу, которая должна иметь дело только с текущей записью в массиве - установить реле в соответствии с первой частью, затем задержать в соответствии со второй частью и перейти к следующей записи. Что-то вроде:

void setup() {
    // Установить выводы реле на выходы
    for (int i = 0; i < 8; i++) {
        pinMode(relayPins[i], OUTPUT);
    }

    // Устанавливаем начальное состояние из первой записи в массиве
    setRelays(states[0].relays);
}

void loop() {
    static uint32_t ts = millis(); // Память на время
    static uint8_t pos = 0; 

    if ((millis() - ts) >= states[pos].postDelay) { // Наше время истекло
        ts = millis(); // Записываем время
        pos++; // переход к следующей записи
        if ((states[pos].relays == 0) && (states[pos].postDelay == 0)) { // Маркер последнего входа
            pos = 0; // Начнем снова с начала
        }
        setRelays(states[pos].relays);
    }
}

// Небольшая вспомогательная функция для установки реле в соответствии с растровым изображением
void setRelays(uint8_t bm) {
    for (int i = 0; i < 8; i++) {
        digitalWrite(relayPins[i], bm & (1 << i));
    }
}

Примечание: этот код не тестировался, он просто написан "экспромтом" и может даже не компилироваться. Но в любом случае это должно дать вам общее представление о методологии.

---

Формат растровых изображений очень прост. Это просто двоичное представление числа, где каждый бит соответствует одному реле. Включите этот бит, и соответствующее реле включится.

• Ретранслятор 1: 0b00000001
• Ретранслятор 2: 0b00000010
• Реле 3: 0b00000100

и т. д. Просто установите 1, чтобы реле было включено, и 0, чтобы реле было выключено в этот момент времени.

Итак, включение реле 1 – это 0b00000001, затем включение реле 4 – 0b00001001, а затем повторное выключение реле 1 – 0b00001000 (реле 4 все еще включено).