Генерация стабильной частоты

Я пытаюсь найти лучший способ генерировать стабильную частоту с помощью моего Uno R3

Я использую прерывания для генерации частоты приблизительно 40 кГц, которая управляет некоторыми ИС/МОП-транзисторами, чтобы эффективно генерировать переменный ток частотой 40 кГц, питающий преобразователь.

Мне нужно получить частоту от второго преобразователя и рассчитать любые сдвиги частоты.

• Проблема в том, что генерируемая частота немного отклоняется от 40 кГц. Есть ли способ зафиксировать его на частоте 40 кГц с помощью программного обеспечения? Я получаю выход примерно 40 кГц (измерено с помощью программного обеспечения PicoScope) с этим кодом:

  #define LEDPIN 13
  void setup()
  {
  pinMode(LEDPIN, OUTPUT);
  // инициализируем Таймер1
  cli();          // отключаем глобальные прерывания
  TCCR1A = 0;     // установить весь регистр TCCR1A в 0
  TCCR1B = 0;     // то же самое для TCCR1B
  // установить сравнение регистра совпадения с желаемым счетчиком таймера:
  OCR1A = 24;
  // включить режим CTC:
  TCCR1B |= (1 << WGM12);
  // Установите CS11 для 8-битного прескалера:
  TCCR1B |= (1 << CS11);
  // включить прерывание сравнения таймера:
  TIMSK1 |= (1 << OCIE1A);
  // разрешить глобальные прерывания:
  sei();
  }
  
  void loop()
  {
  // основная программа
  }
  
   ISR(TIMER1_COMPA_vect)
  {
  digitalWrite(LEDPIN, !digitalRead(LEDPIN));
  }
  

• Если нет способа заблокировать его, есть ли способ, по крайней мере, для Uno точно отображать/сохранять частоту сигнала, который он генерировал в заданное время?

  Или это неправдоподобно, потому что Uno "думает", что генерирует 40 кГц?

Спасибо за любые подсказки или предложения.

EDIT: @RussellMcMahon указал мне правильное направление для этого, поэтому я принял его ответ. Тем не менее, я хотел поделиться своим окончательным кодом и своими неправильными представлениями, с которыми я столкнулся. Надеюсь, это поможет кому-то еще в будущем. Я, очевидно, ни в коем случае не эксперт, и я постараюсь не давать здесь вводящей в заблуждение информации.

Моя первоначальная цель состояла в том, чтобы создать как можно более чистый ШИМ с частотой 40 кГц и коэффициентом заполнения 50 %.

Проблемы с исходным кодом выше:

• Использование 8-битного предварительного масштабирования
• Использование прерывания
• Использование digitalWrite()

8-битный прескейлер
      Проблема здесь заключалась в том, что счетчик тикал только один раз каждые 8 тактов. тактовая частота 16 МГц / 8 (предварительный масштабатор) = тактовая частота 2 МГц Когда я спросил об этом одного из своих профессоров, он сказал что-то вроде «цикл может быть пропущен из-за прерывания, и это приведет к ждать еще 7 циклов, чтобы «тикать»». На самом деле, изначально я использовал прерывания, и когда мы провели расчеты, казалось, что это может привести к колебаниям до 1 кГц на частоте 40 кГц.
      Чтобы исправить это, я отключил предварительный масштабатор и запустил прямо на базовой тактовой частоте, чтобы увеличить разрешение.

Использование прерывания
      По сути, прерывание может привести к тому, что тактовые циклы не будут подсчитываться, что еще больше усложняется использованием 8-битного предварительного масштабатора. Если один такт был пропущен, с тактовой частотой 2 МГц (после предварительного масштабирования) вы добавляете к счетчику 5E-7 секунд, изменяя выходную частоту.

Использование digitalWrite()
      Функция digitalWrite довольно медленная. Я не гуру, но я читал это в нескольких местах, и, кажется, здесь есть хорошее сравнение методов: Колебание цифровых выводов Чтобы обойти эту проблему, было предложено переключить один бит, что я и намеревался сделать в мой окончательный код. (Стоит отметить, что теперь, когда я завершил этот проект, предыдущая ссылка также ссылается на добавление библиотеки для более быстрой цифровой записи/чтения/и т. д....)

Я просмотрел несколько вариантов и собрал код отовсюду и сделал пару рабочих примеров, но они не сделали это так, как я хотел. Я считаю, что частью проекта, на основе которого я создал эту версию, было объединение предыдущей версии, над которой я работал, и примера класса, который я нашел в Интернете.

Без дальнейших церемоний, я представляю код, на написание которого у меня ушло постыдное количество времени из многочисленных источников... Я действительно должен возиться с этим материалом чаще:

#include <avr/io.h>
#include <avr/interrupt.h>
void setup()
{
//Отключить прерывания
cli();
// Очистить регистры Timer1
TCCR1A = 0;
TCCR1B = 0;
// Установите OCR1A (TOP): 16 МГц/40 кГц/2 = 200 шагов.
// Делим 200 на 2 = 100, потому что осциллограммы сосредоточены вокруг OCR1A (из-за переключения)
OCR1A = 100;
// Настройка таймера/счетчика 1
// Выбрать P & F Правильный режим ШИМ и OCR1A в качестве ВЕРХНЕГО. Используйте биты 10 и 13 WGM.
// Биты WGM находятся в TCCR1A и TCCR1B. Любые предыдущие настройки сбрасываются.

// Включить COM1A0 для переключения OC1A при сравнении соответствия
TCCR1A = _BV(WGM10) | _BV(COM1A0);
// CS10 для включения базовых часов без предварительного масштабирования
TCCR1B = _BV(WGM13) | _BV(CS10);

// Установите OC1A (цифровой контакт 9 / порт B, контакт 1) на выход
DDRB |= _BV(1);
}

void loop()
{
}

Для справки, вот формула тактовой частоты. В этом случае мне пришлось снова разделить результат на 2, так как я переключаюсь.

Результирующий вывод проверен PicoScope:

В заключение вы заметите, что это не совсем 40 кГц. Исследования показали, что Arduino Uno использует менее точный керамический резонатор для тактирования ATMEGA328P (хотя для тактирования USB имеется встроенный кварцевый генератор с частотой 16 МГц). Для дальнейшего повышения точности генерируемого сигнала потребуется, чтобы Arduino управлялся внешним источником тактового сигнала.