Как работает функция while(analogRead(A0)) в этом коде?

То, что вы реализовали, возможно, неосознанно, называется гистерезис. Ваша программа проводит большую часть своего времени в любом из этих двух состояний:

1. Он постоянно выполняет внешний цикл while, и считанное значение составляет ≤ 200. Он выходит из этого состояния, как только считывает значение , превышающее 200.
2. Он постоянно запускает внутренний цикл while, и считанное значение > 0. Он выходит из этого состояния только тогда, когда analogRead() возвращает ноль.

Гистерезис-хороший способ подавления шума, когда вы хотите обнаружить сигнал, пересекающий пороговое значение. Однако я бы рекомендовал вам использовать его более контролируемым образом. В частности, второй порог , вероятно, должен быть больше нуля, иначе он не будет преодолен, если сигнал не достигнет уровня земли. Как минимум, вы можете заменить внутренний цикл while чем-то вроде:

while (analogRead(A0) >= 100)
    /* подождите, пока сигнал не станет достаточно низким */;

Для справки, эта логика может быть реализована неблокирующим способом, что позволит программе выполнять другие действия, например, отвечать на нажатия кнопок, ожидая переходов. Для этого вам нужна переменная для записи текущего состояния сигнала (скажем, НИЗКОГО или ВЫСОКОГО) и записи изменений состояния при пересечении соответствующих пороговых значений.

На рисунке ниже реализована эта неблокирующая техника в цикле(), в то время как функция setup() блокирует во время ожидания первого НИЗКОГО → ВЫСОКОГО переход:

const int LOW_THRESHOLD  = 100;
const int HIGH_THRESHOLD = 200;

uint8_t state;      // либо НИЗКОЕ, либо ВЫСОКОЕ
uint8_t count = 0;  // подсчитайте время начала переходов от НИЗКОГО к ВЫСОКОМУ
uint32_t start_time;

void setup() {
    // Дождитесь первого перехода НИЗКИЙ - > ВЫСОКИЙ.
    while (analogRead(A0) >= LOW_THRESHOLD)
        /* Дождитесь НИЗКОГО состояния. */;
    while (analogRead(A0) < HIGH_THRESHOLD)
        /* Дождитесь ВЫСОКОГО состояния. */;
    state = HIGH;

    // Запишите время перехода.
    start_time = millis();
}

void loop() {
    // Запись переходов.
    uint8_t val = analogRead(A0);
    if (state == HIGH && val < LOW_THRESHOLD) {
        state = LOW;
    } else if (state == LOW && val >= HIGH_THRESHOLD) {
        state = HIGH;
        ++count;
    }

    if (count >= 5) {
        // Сообщить об измеренной частоте.
        uint32_t end_time = millis();
        int frequency = 1000 * count / (end_time - start_time);
        Serial.println(frequency);

        // Готовьтесь к следующему раунду.
        start_time = end_time;
        count = 0;
    }
}