Переключатель лампы Adafruit Featherwing Latching Relay

Я добавлю сюда окончательный код. Мне потребовались недели, чтобы найти отправную точку, и много часов проб и ошибок, чтобы разобраться во всем этом. С его помощью мне удалось получить стабильно работающий коммутатор.

Этот код был написан для Wemos D1 Mini, соединенного с реле фиксации Adafruit Featherwing. Поскольку он устанавливал и отменял кодирование контактов, это была борьба для меня. Установленные/неустановленные контакты требуют только импульса для их запуска, после чего они остаются "запертыми" в состоянии. даже если сила будет потеряна. Я нашел здесь базовый код, и потребовалось немного подправить его, чтобы заставить работать.

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>

// Замените свои сетевые учетные
const char* ssid = "SSID";
const char* password = "PASSWORD";

ESP8266WebServer server(80);   //создать экземпляр сервера на порту 80 (http-порт)

String page = "";
int LEDUnsetPin = D1;
int LEDSetPin = D2;
void setup(void){
 //HTML веб - страницы
 //не забывайте, что вам нужны estapes (") вокруг страницы котировок
 page = "<style>  .button{    background-color:red;    color:blue;    border-radius: 8px;    padding: 12px 24px;  }</style><h1>Kitchen LEDs</h1><p>    <a href=\"LEDOn\"><button class=\"button\">ON</button></a>    &nbsp;    <a href=\"LEDOff\"><button>OFF</button></a></p>";
 //сделайте вывод светодиодных контактов и изначально выключите
 pinMode(LEDUnsetPin, OUTPUT);
 digitalWrite(LEDUnsetPin, LOW);
 pinMode(LEDSetPin, OUTPUT);
 digitalWrite(LEDSetPin, LOW);

 delay(1000);
 Serial.begin(115200);
 WiFi.begin(ssid, password); //начать подключение Wi-Fi
 Serial.println("");

 // Подождите подключения
 while (WiFi.status() != WL_CONNECTED) {
   delay(500);
   Serial.print(".");
 }
 Serial.println("");
 Serial.print("Connected to ");
 Serial.println(ssid);
 Serial.print("IP address: ");
 Serial.println(WiFi.localIP());

 server.on("/", [](){
   server.send(200, "text/html", page);
 });

 //включите pin on и выключите сервер off pin
 server.on("/LEDOn", [](){
   server.send(200, "text/html", page);
   digitalWrite(LEDSetPin, HIGH);
   delay(10);
   digitalWrite(LEDSetPin, LOW);
   delay(10);
 });

 //выключите pin включения и включите
 server.on("/LEDOff", [](){
   server.send(200, "text/html", page);
   digitalWrite(LEDUnsetPin, HIGH);
   delay(10);
   digitalWrite(LEDUnsetPin, LOW);
   delay(10);
 });
 server.begin();
 Serial.println("Web server started!");
}

void loop(void){
 server.handleClient();
}