Проблемы с драйвером двигателя L298N

Надеюсь, я вас правильно понял. Лучший способ - рассказать вам, как вы можете использовать состояния для решения проблемы. Но это отняло бы у меня слишком много времени.

Я решил отредактировать вашу программу. У меня нет оборудования, чтобы попробовать это. Так что это просто пример, чтобы показать вам эту идею. Возможно, это работает так, как есть.

Пожалуйста, проверьте комментарии. Если вы действительно заинтересованы в понимании проблемы и решения, а вещи неясны, вы (или другие) можете спросить с комментариями ниже. И конечно, если вы найдете ошибку, я буду рад узнать об этом и исправить ее. ;-)

#include <Wire.h>
#include <LiquidCrystal_I2C.h>


// Это разные состояния движения
#define STATE_STOP 0
#define STATE_LEFT 1
#define STATE_RIGHT 2
#define STATE_FORWARD 3
#define STATE_BACKWARD 4

// всегда используйте выразительные имена

// Назначение выводов
//////////////////////////////////////////////

// Analog
int pinPotiSpeed = A0;

// Двигатель A
int pinEnA = 9;
int pinInA1 = 8;
int pinInA2 = 7;

// Двигатель B
int pinEnB = 3;
int pinInB1 = 5;
int pinInB2 = 4;

// Кнопки
const int pinBtnDir = 10;
const int pinBtnTurn = 11 ;

int stateMotors = STATE_STOP;
boolean flagBtnDirPressed = LOW;
boolean flagBtnTurnPressed = LOW;

int stateMotorsSpeed = 0;
int speedPercent = map( stateMotorsSpeed, 0, 255, 0, 100 );

LiquidCrystal_I2C lcd(0x27, 16, 2);

// У меня нет времени много думать об этом разоблачении, но
// У меня плохое предчувствие. Если Arduino не реагирует на нажатия кнопок 
// или смена режима на быстрый, пожалуйста, дайте мне знать. Я посмотрю на это, если
// необходимо. ;-)
boolean readButtonAndDebounce(int btnPin, boolean lastState)
{
    boolean actualState = digitalRead(btnPin);
    if (lastState != actualState) 
    {
      delay(15);
      actualState = digitalRead(btnPin);
      return actualState;
    }

    // этот возврат отсутствовал в исходной программе
    return actualState;
}

void setup() 
{
    Serial.begin(9600);

    pinMode(pinEnA, OUTPUT);
    pinMode(pinInA1, OUTPUT);
    pinMode(pinInA2, OUTPUT);

    pinMode(pinEnB, OUTPUT);
    pinMode(pinInB1, OUTPUT);
    pinMode(pinInB2, OUTPUT);

    pinMode(pinBtnDir, INPUT);
    pinMode(pinBtnTurn, INPUT);

    digitalWrite(pinInA1,LOW);
    digitalWrite(pinInA2,LOW);
    
    digitalWrite(pinInB1,LOW);
    digitalWrite(pinInB2,LOW);

    lcd.init();
    lcd.backlight();

    

    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("SPEED:");
    lcd.setCursor(0, 1);

    lcd.setCursor(7, 0);
    // преобразовать 0-255 в 0%-100%
    lcd.print ("0 %");

    lcd.setCursor(0, 1);
    lcd.print("MOVE: Stop");
}

void loop() 
{
    stateMotorsSpeed = map( analogRead( pinPotiSpeed ), 0, 1023, 0, 255 );
    if ( stateMotorsSpeed < 8 ) stateMotorsSpeed = 0;
    speedPercent = map( stateMotorsSpeed, 0, 255, 0, 100 );

    boolean flagBtnDirPressedOld = flagBtnDirPressed;
    flagBtnDirPressed = readButtonAndDebounce( pinBtnDir, flagBtnDirPressed );

    boolean flagBtnTurnPressedOld = flagBtnTurnPressed;
    flagBtnTurnPressed = readButtonAndDebounce( pinBtnTurn, flagBtnTurnPressed );


    // this is a bit tricky, because I don't know if i understood the problem correctly.
    // Моя проблема в том, что произойдет, если обе кнопки будут нажаты, я решил дать 
    // кнопка направления приоритет
    if ( flagBtnDirPressed && ! flagBtnDirPressedOld )
    {
      switch( stateMotors )
      {
        case STATE_STOP:
          stateMotors = STATE_FORWARD;
          break;
        
        case STATE_FORWARD:
          stateMotors = STATE_BACKWARD;
          break;
      
        case STATE_BACKWARD:
          stateMotors = STATE_STOP;
          break;

        default:
          // это происходит, если состояние из другой кнопки активно
          // В таблице нет правила, что делать в этом случае.
          // Возможно, вы могли бы посчитать нажатие кнопки по модулю 3 для каждой кнопки
          // и тогда вы можете переключиться в правильное состояние
          stateMotors = STATE_STOP;
      }

    }
    else if ( flagBtnTurnPressed && ! flagBtnTurnPressedOld )
    {
      // вводится только в том случае, если состояние нажатия кнопки направления не изменилось
      switch( stateMotors )
      {
        case STATE_STOP:
          stateMotors = STATE_RIGHT;
          break;
        
        case STATE_RIGHT:
          stateMotors = STATE_LEFT;
          break;

        case STATE_LEFT:
          stateMotors = STATE_STOP;
          break;

        default:
          // это происходит, если состояние из другой кнопки активно
          stateMotors = STATE_STOP;
      }
    }

    controlMotorAndUpdateLcd();
}

void setMotorSignals( boolean sigA1 , boolean sigA2, boolean sigB1, boolean sigB2 )
{
      //MOTOR_A
      digitalWrite(pinInA1, sigA1);
      digitalWrite(pinInA2, sigA2);

      //MOTOR_B
      digitalWrite(pinInB1, sigB1);
      digitalWrite(pinInB2, sigB2);
}
  
void controlMotorAndUpdateLcd() 
{
    lcd.clear();
    lcd.setCursor( 0, 0 );
    lcd.print( "SPEED:" );
    lcd.setCursor( 0, 1 );

    // потенциометр LCD
    lcd.setCursor( 7, 0 );
    lcd.print ( speedPercent );
    lcd.setCursor( 12, 0 );
    lcd.print ("%");

    analogWrite ( pinEnA, stateMotorsSpeed );
    analogWrite ( pinEnB, stateMotorsSpeed );

    // MotorLCD
    lcd.setCursor(0, 1);
    lcd.print("MOVE:");

    lcd.setCursor(5, 8);
    switch( stateMotors )
    {
      case STATE_STOP:
        lcd.print("Stop");
        setMotorSignals( LOW, LOW, LOW, LOW);
        break;
        
      case STATE_FORWARD:
        lcd.print("Forward");
        setMotorSignals( HIGH, LOW, HIGH, LOW);
        break;
      
      case STATE_BACKWARD:
        lcd.print("Reverse");
        setMotorSignals( LOW, HIGH, LOW, HIGH);
        break;

       case STATE_LEFT:
        lcd.print("Left");
        setMotorSignals( HIGH, LOW, LOW, HIGH);
        break;
      
      case STATE_RIGHT:
        lcd.print("Right");
        setMotorSignals( LOW, HIGH, HIGH, LOW);
        break;
    }
}