Какой режим DLMS вы используете?

IEC 61107 или в настоящее время IEC 62056-21 — это международный стандарт компьютерного протокола для считывания показаний счетчиков коммунальных услуг. Он предназначен для работы через любые носители, включая Интернет. Счетчик отправляет данные ASCII (в режимах A..D) или HDLC (режим E) на ближайший переносной блок (HHU) через последовательный порт. МЭК 62056

В своем вопросе вы упомянули:

шестнадцатеричная строка

что означает строку шестнадцатеричных символов с использованием ASCII (режимы от A до D).

Однако в комментариях вы упомянули:

void ReactivePower(unsigned char data[], int dataSize) String reacP = String(data[dataSize - 5], HEX) + String(data[dataSize - 4], HEX);

что означает массив байтов, полученный из потока байтов с использованием HDLC (режим E).

ASCII (режимы от A до D)

Для ASCII (режимы от A до D) существует простое преобразование, чтобы получить цифровое значение из шестнадцатеричного символа.

              ASCII
 Hex   --------------------                            Digit
 char  Decimal  Hexadecimal    Op1    Low nibble  Op2  Base 10
-----  -------  -----------  -------  ----------  ---  -------
 '0'      48        30        & 0x0F       0              0
 '1'      49        31        & 0x0F       1              1
 '2'      50        32        & 0x0F       2              2
 '3'      51        33        & 0x0F       3              3
 '4'      52        34        & 0x0F       4              4
 '5'      53        35        & 0x0F       5              5
 '6'      54        36        & 0x0F       6              6
 '7'      55        37        & 0x0F       7              7
 '8'      56        38        & 0x0F       8              8
 '9'      57        39        & 0x0F       9              9
 'A'      65        41        & 0x0F       1       +9    10
 'B'      66        42        & 0x0F       2       +9    11
 'C'      67        43        & 0x0F       3       +9    12
 'D'      68        44        & 0x0F       4       +9    13
 'E'      69        45        & 0x0F       5       +9    14
 'F'      70        46        & 0x0F       6       +9    15
 'a'      97        61        & 0x0F       1       +9    10
 'b'      98        62        & 0x0F       2       +9    11
 'c'      99        63        & 0x0F       3       +9    12
 'd'     100        64        & 0x0F       4       +9    13
 'e'     101        65        & 0x0F       5       +9    14
 'f'     102        66        & 0x0F       6       +9    15

• Для символов от '0' до '9' просто используйте И с 0x0F.
• Для символов от "A" до "F" и от "a" до "f", AND с 0x0F и добавить 9.

char ch = '1';
byte b = 0;
if (ch >= '0' && ch <= '9')
{
  b = ch & 0x0F;
}
else if ((ch >= 'A' && ch <= 'F') || (ch >= 'a' && ch <= 'f'))
{
  b = (ch & 0x0F) + 9;
}

Также важно знать, было ли преобразование успешным, например, первый символ может быть неправильным (будь то нулевой терминатор или не шестнадцатеричный символ), поэтому это необходимо проверить во время преобразования. Кроме того, в int16 есть четыре полубайта, поэтому преобразование необходимо завершить, когда будет обработано максимум четыре шестнадцатеричных символа:

void setup()
{
  pinMode(13, OUTPUT);
  Serial.begin(115200);
}

void loop()
{
  char string[] = "A";
  //char string[] = "Вафля";
  //символьная строка[] = "ff9d";
  int16_t the_int = 0;
  int count = AsciiToInt16(string, the_int);

  Serial.print(string);
  Serial.print(",  ");
  if (count)
  {
    Serial.print("Ok,  ");
    Serial.print(count);
    Serial.print(",  ");
    Serial.println(the_int);
  }
  else
  {
    Serial.println("Bad");
  }
}

int AsciiToInt16(const char* ch, int16_t& value)
{
  int count = 0;
  byte nibble = 0;

  // Остановиться после 4-го полубайта или нулевого ограничителя.
  for(int i = 0; i < 4 && ch[i] != 0; i++)
  {
    if (AsciiToNibble(ch[i], nibble))
    {
      value <<= 4;
      value |= nibble;
      count++;
    }
    else
    {
      break;  // Остановиться после не шестнадцатеричной цифры.
    }
  }
  return count;
}

bool AsciiToNibble(const char ch, byte& b)
{
  if (ch >= '0' && ch <= '9')
  {
    b = ch & 0x0F;
    return true;
  }
  else if ((ch >= 'A' && ch <= 'F') || (ch >= 'a' && ch <= 'f'))
  {
    b = (ch & 0x0F) + 9;
    return true;
  }
  return false;
}

Вывод

A,  Ok,  1,  10
Waffle,  Bad
ff9d,  Ok,  4,  -99

HDLC (режим E)

Для HDLC (режим E) просто выполните:

void ReactivePower(byte data[], int dataSize)
{
  uint16_t reacP = (data[dataSize - 5] << 8) | data[dataSize - 4];
  Serial.println(dataSize);
  Serial.println(reacP);
}
. . .
  byte data[] = { 1, 3, 5, 2, 4, 8 };
  ReactivePower(data, sizeof(data));

Вывод

6
773