не удается подключиться к веб-серверу ESP8266 через некоторое время

Question

не удается подключиться к веб-серверу ESP8266 через некоторое время

esp8266

Я новичок в ESP8266 и нашел пример включения/выключения светодиода с помощью веб-интерфейса. Он работает хорошо, но через некоторое время (несколько минут) я не могу открыть веб-страницу (в моем случае это http://192.168.100.23, и я сделал статический IP). Он продолжает «ждать 192.168.100.23». Я могу пропинговать IP. Может кто-нибудь помочь найти в чем проблема? Большое спасибо!

Ниже приведен код:

#include <ESP8266WiFi.h>
#define LED D2
const char* ssid = "myAP";
const char* password = "32133213";
unsigned char status_led=0;
WiFiServer server(80);

void setup() {
  Serial.begin(115200);
  pinMode(LED, OUTPUT);
  /*WiFi.persistent( false );
  WiFi.setAutoConnect(true);
  WiFi.mode(WIFI_STA);*/
  Serial.println();
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) 
  {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  server.begin();
  Serial.println("Server started");
  Serial.println(WiFi.localIP());
}

void loop() {
  WiFiClient client = server.available();
  if (!client) {
    return;
  }

  Serial.println("new client");
  while(!client.available())
  {
    delay(1);
  }
  String req = client.readStringUntil('\r');
  Serial.println(req);
  client.flush();
  if (req.indexOf("/ledoff") != -1)
  {
    status_led=0;   
    digitalWrite(LED,LOW);
    Serial.println("LED OFF");
  }
  else if(req.indexOf("/ledon") != -1)
  {
    status_led=1;
    digitalWrite(LED,HIGH);
    Serial.println("LED ON");
  }
  String web = "HTTP/1.1 200 OK\r\nContent-Type: text/html\r\n\r\n";
  web += "<html>\r\n";
  web += "<body>\r\n";
  web += "<h1>LED Status</h1>\r\n";
  web += "<p>\r\n";
  if(status_led==1)
      web += "LED On\r\n";
  else
      web += "LED Off\r\n";
  web += "</p>\r\n";
  web += "</p>\r\n";
  web += "<a href=\"/ledon\">\r\n";
  web += "<button>LED On</button >\r\n";
  web += "</a>\r\n";
  web += "</p>\r\n";

  web += "<a href=\"/ledoff\">\r\n";
  web += "<button>LED Off</button >\r\n";
  web += "</a>\r\n";

  web += "</body>\r\n";
  web += "</html>\r\n";

  client.print(web);
}

@don bradly, 👍1

2 ответа

Лучший ответ:

▲ 1

ESP8266 переходит в спящий режим модема в режиме STA без трафика WiFi. Вы можете отключить спящий режим с помощью WiFi. /а>. Возможные параметры: WIFI_NONE_SLEEP, WIFI_LIGHT_SLEEP или WIFI_MODEM_SLEEP.

По прошествии некоторого времени серверы на esp8266 с ядром arduino обычно становятся недоступными, даже если esp8266 подключается как клиент к другим серверам или по-прежнему отправляет сообщения UDP. Это известная проблема с задокументированными возможными обходными путями.

17 фев 20, @Juraj

Большое спасибо за быстрый ответ. Я поработаю над этим., @don bradly

@*don bradly* · Accepted Answer · 2020-02-18 03:09-00:00

Я добавил WiFi.setSleepMode(WIFI_NONE_SLEEP); но это не помогает. Я нашел еще один скрипт, который до сих пор работает хорошо (через 1 день). Я новичок, поэтому не знаю, в чем проблема, но думаю, что нужно освободить память и закрыть соединение. Ниже приведен новый код для тех, у кого такая же проблема!

// Load Wi-Fi library
#include <ESP8266WiFi.h>
#define LED D2
// Replace with your network credentials
const char* ssid     = "myAP";
const char* password = "32133213";
// Set web server port number to 80
WiFiServer server(80);
// Variable to store the HTTP request
String header;
// Auxiliar variables to store the current output state
String outputState = "off";
// Assign output variables to GPIO pins

// Current time
unsigned long currentTime = millis();
// Previous time
unsigned long previousTime = 0; 
// Define timeout time in milliseconds (example: 2000ms = 2s)
const long timeoutTime = 2000;
void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(LED, OUTPUT);
  // Set outputs to LOW
  digitalWrite(LED, LOW);

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}
void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients
  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    currentTime = millis();
    previousTime = currentTime;
    while (client.connected() && currentTime - previousTime <= timeoutTime) { // loop while the client's connected
      currentTime = millis();         
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();

            // turns the GPIOs on and off
            if (header.indexOf("GET /on") >= 0) {
              Serial.println("light on");
              outputState = "on";
              digitalWrite(LED, HIGH);
            } else if (header.indexOf("GET /off") >= 0) {
              Serial.println("light off");
              outputState = "off";
              digitalWrite(LED, LOW);
            } 

            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #77878A;}</style></head>");

            // Web Page Heading
            client.println("<body><h1>ESP8266 Web Server</h1>");

            // Display current state, and ON/OFF buttons for GPIO 5  
            client.println("<p>State " + outputState + "</p>");
            // If the output5State is off, it displays the ON button       
            if (outputState=="off") {
              client.println("<p><a href=\"/on\"><button class=\"button button2\">TURN ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/off\"><button class=\"button\">TURN OFF</button></a></p>");
            } 

            client.println("</body></html>");

            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}