Термопара и мультиметр

Ваш код не очень длинный, но я уже вижу несколько вещей, которые я бы изменил.

int analogPin = 0;
[...]
pinMode(A4, INPUT);

Эти способы использования булавок противоречивы. Я лично предпочитаю настройки в начале файла, поэтому я ожидаю

int analogPin = 0;
int whateverPin = A4;  // У меня пока нет хорошего имени

Пока у вас есть

pinMode(A4, INPUT);

нет

pinMode(analogPin, INPUT);

Основной цикл выполняет две функции: а) показывает показания температуры и б) показывает спецификации компонентов. Это было бы более очевидно, если бы было написано так:

void loop() {
  input = analogRead(A4); // функция AnalogRead используется для получения аналоговых данных
  volt = (input * 5.0) / 1024.0; //формула, используемая для выполнения действия

  showTemperatureReadings();
  showComponentReadings();    
}

Вы не находите, что это выглядит немного странно? А как насчет того, что было до этих двух больших методов show...()? Эти две строки явно принадлежат showComponentReadings().

Теперь многие переменные объявляются вне методов. Это делает их глобальными переменными. Их можно изменить из любого места в коде. Когда проект растет, побочные эффекты — это зло. Давайте удалим как можно больше из них.

Вы можете избавиться от:

int input = 0;
float volt = 0;
float buffer = 0;
float R2 = 0;
float Vout = 0;
int raw = 0;

Я думаю, что после этого изменения метод setup() мог бы быть более кратким. Многое связано только с датчиком температуры. Я бы тоже извлек метод.

Сообщения об ошибках, подобные

Устройство не подтвердило! Замораживание.

не может иметь большого значения для пользователя. Сообщение типа

Датчик температуры не подтвердился! Проверьте проводку и нажмите кнопку сброса, чтобы повторить попытку.

может дать более содержательные инструкции.

Окончательный код с этими предложениями:

#include <SparkFun_MCP9600.h>
MCP9600 tempSensor;
int analogPin = 0;
int whateverPin = A4;
float R1 = 220;
int Vin = 5;

void setupTemperatureSensor() {
  tempSensor.begin();
  if (tempSensor.isConnected()) {
    Serial.println("Temperature sensor acknowledged.");
  }
  else {
    Serial.println("Temperature sensor did not acknowledge! Check the wiring and press the reset button to retry.");
    while (1); //висеть навсегда
  }

  if (tempSensor.checkDeviceID()) {
    Serial.println("Temperature sensor ID is correct.");
  }
  else {
    Serial.println("The temperature sensor ID does not have the expected value. Do you use a different sensor type? Use a SparkFun MCP9600.");
    while (1);
  }
}

void setup() {
  Serial.begin(115200);
  Wire.begin();
  Wire.setClock(100000);

  setupTemperatureSensor();

  pinMode(whateverPin, INPUT);
  pinMode(analogPin, INPUT);
}

void showTemperatureReadings() {
    if (tempSensor.available()) {
    Serial.print("Thermocouple: ");
    Serial.print(tempSensor.getThermocoupleTemp());
    Serial.print(" °C   Ambient: ");
    Serial.print(tempSensor.getAmbientTemp());
    Serial.print(" °C   Temperature Delta: ");
    Serial.print(tempSensor.getTempDelta());
    Serial.print(" °C");
    Serial.println();
  }
}

void showComponentReadings() {
  int input = analogRead(whateverPin); // функция AnalogRead используется для получения аналоговых данных
  float volt = (input * 5.0) / 1024.0; //формула, используемая для выполнения действия
  int raw = analogRead(analogPin);
  if (raw)
  {
    float buffer = raw * Vin;
    float Vout = (buffer) / 1024.0;
    buffer = (Vin / Vout) - 1;    
    float R2 = R1 * buffer;
    Serial.print("Vout: ");
    Serial.println(Vout);
    Serial.print("R2: ");
    Serial.println(R2);
    Serial.print("voltage is:");
    Serial.println(volt);
    Serial.print("current is:");
    Serial.println(volt / R2);
    delay(1000);
  }
}

void loop() {
  showTemperatureReadings();
  showComponentReadings();
}

С активным свертыванием кода, я бы сказал, теперь очень просто получить представление о том, что делает код и что можно настроить:

Изменить:

После того, как вы дали ссылку на схему, я бы

• переименуйте любой контакт в voltageDividerPin.
• изменить вычисление float volt = (input * 5.0) / 1024.0; на сопоставление, поскольку оно сопоставляет 1024 входных значений с 5 В, поэтому float volt = map(voltageReading, 0 , 1024, 0, Вин);
• полностью удалите analogPin, так как он также не используется в исходном коде.

Я также надеюсь, что прочитал статью и понял последствия использования резистора на 220 Ом.