вывод становится высоким, не позволяя аналоговому чтению измениться

Описание, которое вы даете для желаемого поведения, очень нечеткое и тяжело следовать. Я собираюсь перефразировать то, что, как мне кажется, я понял в с точки зрения конечного автомата, что является правильным способом описание такого рода систем. Пожалуйста, ознакомьтесь с описанием ниже, скорее всего, я не совсем понял, чего вы на самом деле хотите.

Допустим, система может находиться в любом из этих трех состояний:

• В состоянии V_LOW входное напряжение ниже порогового значения X и выход LOW. Если ввод превышает X, мы устанавливаем вывод в HIGH и перейти в состояние V_HIGH.

• В состоянии V_HIGH ввод выше порогового значения X, а вывод HIGH. Если ввод падает ниже X, мы возвращаемся к Состояние V_LOW. Если мы остаемся в V_HIGH в течение трех секунд, мы переключаемся вывод в LOW и переход в состояние TIMEOUT.

• В состоянии TIMEOUT ввод превышает пороговое значение, но выход LOW. Когда ввод падает ниже X, мы переходим к V_LOW состояние.

Ниже показан график состояния этой машины. Штаты с серым фон имеет вывод LOW, тогда как состояние с белым background имеет вывод HIGH. Каждый возможный переход изображается как стрелка, помеченная условием, запускающим переход:

Это то поведение, которое вы имеете в виду? Если нет, попробуйте описать поведение, которое вы хотите с точки зрения конечного автомата, как я сделал здесь. Если да, то я предлагаю вам последовать совету Крисла и реализовать некоторый гистерезис из-за разных порогов входа и выхода из V_LOW.

Во всяком случае, ниже приведен перевод вышеприведенного FSM на C++. А может и не быть самый эффективный способ написать это, но я считаю, что это просто достаточно, чтобы не требовать дополнительных объяснений:

void update_output()
{
    static enum { V_LOW, V_HIGH, TIMEOUT } state;
    static uint32_t time_entered_v_high;
    int V = analogRead(A0);

    switch (state) {
    case V_LOW:
        if (V >= X) {
            digitalWrite(pin, HIGH);
            state = V_HIGH;
            time_entered_v_high = millis();
        }
        break;
    case V_HIGH:
        if (V < X) {
            digitalWrite(pin, LOW);
            state = V_LOW;
        } else if (millis() - time_entered_v_high >= 3000) {
            digitalWrite(pin, LOW);
            state = TIMEOUT;
        }
        break;
    case TIMEOUT:
        if (V < X) {
            state = V_LOW;
        }
        break;
    }
}

Обновление 1: Вот как реализовать гистерезис: вам нужно выбрать второй, нижний порог, для возврата в состояние V_LOW. Давай позвоним это Y, который меньше, чем X. Тогда как на схеме, так и на кода, замените каждый экземпляр «V < X» на «V < Й». Вот и все. Есть абсолютно нечего больше менять.

Правка 2: обращение к обновленному вопросу. Теперь вывод должен идти HIGH, когда входные данные выходят за пределы определенного диапазона. добавлю гистерезис сразу, используя четыре порога V₀ < V₁ < V₂ < V₃ :

• ввод в пределах диапазона, если он находится в пределах [V₁, V₂)

• ввод вне диапазона, если он не в пределах [V₀, V₃)

• диапазоны [V₀, V₁) и [V₂, V₃) обеспечивают гистерезис.

Обратите внимание, что для согласованности я предпочитаю закрывать все интервалы на та же сторона. Я также переименую состояния V_LOW и V_HIGH в IN_RANGE и OUT_OF_RANGE соответственно. Вот обновленный код:

void update_output()
{
    static enum { IN_RANGE, OUT_OF_RANGE, TIMEOUT } state;
    static uint32_t time_exited_range;
    int V = analogRead(A0);

    switch (state) {
    case IN_RANGE:
        if (V < V0 || V >= V3) {
            digitalWrite(pin, HIGH);
            state = OUT_OF_RANGE;
            time_exited_range = millis();
        }
        break;
    case OUT_OF_RANGE:
        if (V >= V1 && V < V2) {
            digitalWrite(pin, LOW);
            state = IN_RANGE;
        } else if (millis() - time_exited_range >= 3000) {
            digitalWrite(pin, LOW);
            state = TIMEOUT;
        }
        break;
    case TIMEOUT:
        if (V >= V1 && V < V2) {
            state = IN_RANGE;
        }
        break;
    }
}