Какие диоды использовать в матричном вводе кнопок/клавиш? (Изготовление игровой клавиатуры)

Когда я использовал матрицу клавиатуры, я подключал ее следующим образом:

Я использовал SMD-диоды 1N4148, которые купил по дешевке. Я вырезал дорожки на своей дешевой плате, купленной в Jaycar, и припаял их вот так:

Точка — это катод (на моих диодах на конце катода выгравирована линия).

Резисторы номиналом 10 кОм эффективно превращают столбцы в подтягивающие, поэтому нет опасности, что плохой код повредит Arduino или что-то еще.

Пример кода для сканирования матрицы:

// Keypad_Decoder
//
// Автор: Ник Гэммон
// Дата: 17 февраля 2018 г.

// Вывод в Serial в формате: 0b1nnnnnn для нажатия клавиши и 0b0nnnnnn для нажатия клавиши
// nnnnnn будет текущей комбинацией строки/столбца
// Также каждый HEARTBEAT_TIME выводит 0xFF, если все ключи нажаты (пульс)

#include <limits.h>     /* for CHAR_BIT */

const byte ROWS = 4;
const byte COLS = 4;
const bool ENABLE_PULLUPS = true;  // сделайте false, если вы используете внешние подтягивания
const unsigned long DEBOUNCE_TIME = 10;     // миллисекунды
const unsigned long HEARTBEAT_TIME = 2000;  // миллисекунды
const bool DEBUGGING = false;               // делаем true для удобочитаемого вывода

// определяем здесь, где каждая строка и столбец соединены с
const byte rowPins [ROWS] = {6, 7, 8, 9}; //подключаемся к распиновке ряда клавиатуры
const byte colPins [COLS] = {2, 3, 4, 5}; //подключаем к колонке распиновку клавиатуры


// См.: http://c-faq.com/misc/bitsets.html

#define BITMASK(b) (1 << ((b) % CHAR_BIT))
#define BITSLOT(b) ((b) / CHAR_BIT)
#define BITSET(a, b) ((a)[BITSLOT(b)] |= BITMASK(b))
#define BITCLEAR(a, b) ((a)[BITSLOT(b)] &= ~BITMASK(b))
#define BITTEST(a, b) ((a)[BITSLOT(b)] & BITMASK(b))

// количество элементов в массиве
#define ARRAY_SIZE(x) (sizeof(x) / sizeof((x)[0]))

// общее количество ключей
const byte TOTAL_KEYS = ROWS * COLS;

// запомнить предыдущую настройку каждой клавиши
char lastKeySetting [(TOTAL_KEYS + CHAR_BIT - 1) / CHAR_BIT];  // по одному биту, 0 = вверх, 1 = вниз
unsigned long lastKeyTime [TOTAL_KEYS];       // когда этот ключ последний раз менялся
unsigned long lastHeartbeat;                  // когда мы в последний раз отправляли сердцебиение

void setup ()
{
  Serial.begin (115200);
  while (!Serial) { }  // ждем готовности Serial (Леонардо и т.д.)

  // установить для каждого столбца значение input-pullup (необязательно)
  if (ENABLE_PULLUPS)
    for (byte i = 0; i < COLS; i++)
      pinMode (colPins [i], INPUT_PULLUP);

}  // конец настройки

void loop ()
  {
  byte keyNumber = 0;
  unsigned long now = millis ();  // для устранения дребезга

  // проверяем каждую строку
  for (byte row = 0; row < ROWS; row++)
    {
    // устанавливаем для этой строки значение OUTPUT и LOW
    pinMode (rowPins [row], OUTPUT);
    digitalWrite (rowPins [row], LOW);

    // проверяем каждый столбец, чтобы убедиться, что переключатель не установил для этого столбца НИЗКИЙ уровень
    for (byte col = 0; col < COLS; col++)
      {
      // debounce - игнорировать, если с момента последнего изменения прошло недостаточно времени
      if (now - lastKeyTime [keyNumber] >= DEBOUNCE_TIME)
        {
        bool keyState = digitalRead (colPins [col]) == LOW; // true означает нажатие
        if (keyState != (BITTEST (lastKeySetting, keyNumber) != 0)) // изменилось?
          {
          lastKeyTime [keyNumber] = now;  // запоминаем время, когда оно изменилось
          // запомнить новое состояние
          if (keyState)
            BITSET (lastKeySetting, keyNumber);
          else
            BITCLEAR (lastKeySetting, keyNumber);
          if (DEBUGGING)
            {
            Serial.print (F("Key "));
            Serial.print (keyNumber);
            if (keyState)
              Serial.println (F(" down."));
            else
              Serial.println (F(" up."));
            }  // при отладке
          else
            Serial.write ((keyState ? 0x80 : 0x00) | keyNumber);
          }  // если состояние ключа изменилось
        }  // время устранения дребезга вверх
      keyNumber++;
      } // конец каждого столбца

    // возвращаем строку в состояние высокого импеданса (вход)
    pinMode (rowPins [row], INPUT);
    }  // конец каждой строки

  // Отправлять код сердцебиения (0xFF) каждые несколько секунд на случай, если
  // получатель случайно теряет нажатие клавиши.
  // Отправка только в том случае, если все клавиши не нажаты (предположительно нормальное состояние).
  if (now - lastHeartbeat >= HEARTBEAT_TIME)
    {
    lastHeartbeat = now;
    bool allUp = true;
    for (byte i = 0; i < ARRAY_SIZE (lastKeySetting); i++)
      if (lastKeySetting [i])
        allUp = false;
    if (allUp)
      {
      if (DEBUGGING)
        Serial.println (F("No keys pressed."));
      else
        Serial.write (0xFF);
      } // конец всех ключей вверх
    } // конец, если время для сердцебиения
  } // конец цикла

Что касается скорости, я измерил около 300 мкс при сканировании без нажатия клавиш. Если это время покажется вам слишком большим, вы всегда можете проверить время и сканировать каждые 5 мс или около того.

У меня есть сообщение обо всем этом на моем форуме. В этом посте я также упоминаю библиотеку, которая обрабатывает одновременное нажатие нескольких клавиш, поэтому вы можете обнаружить одновременное нажатие нескольких клавиш. Например, вы можете использовать A/B/C/D на клавиатуре в качестве клавиш «Shift», чтобы A+1 означало нечто иное, чем просто 1.

Матрица спереди:

Моя проблема в том, какие диоды использовать, а также почему именно этот тип (или почему это не имеет значения).

Я не думаю, что конкретный диод в данном случае имеет решающее значение. Если бы это было очень высокоскоростное приложение, то мог бы потребоваться диод с быстрым переключением. Если бы это было высокое напряжение, то мог бы потребоваться диод с более высокими характеристиками. В некоторых случаях может применяться обратное напряжение. В данном конкретном случае, поскольку мы имеем дело с включением/выключением на логических уровнях, я не думаю, что это имеет большое значение, хотя скорость переключения может быть в определенной степени, однако я предполагаю из эмпирических наблюдений, что скорость 1N4148 достаточно быстро.

Также см.: Википедия — 1N4148:

Модуль 1N4148 полезен в коммутационных приложениях с частотой до 100 МГц и временем обратного восстановления не более 4 нс.