Где мой БАГ?

Я вижу пару проблем с вашим кодом. Самая большая проблема заключается в том, что вы записываете startMillis в setup (), а затем сравниваете его с текущими миллионами в своем цикле. Если для того, чтобы горшок достаточно нагрелся, потребуется более пяти секунд, вы никогда не будете соответствовать (currentMillis - startMillis) == период, потому что (currentMillis - startMillis) уже будет > период, прежде чем вы начнете его тестировать. Изменение "== период" на ">= период" исправит это, но оно все равно будет вести себя не так, как вы хотите, так как вы должны устанавливать startMillis, когда банк впервые достиг целевой температуры, а не при запуске программы.>

Кроме того, ваш код ничего не делает, когда температура находится между НИЖНЕЙ и ВЕРХНЕЙ ГРАНИЦЕЙ, что, как я подозреваю, не то, что вам нужно. Вы не указываете, означает ли "до температуры" значение на уровне или выше НИЖНЕГО ПРЕДЕЛА или на уровне или выше ВЕРХНЕГО ПРЕДЕЛА. Я собираюсь предположить, что вы хотите, чтобы светодиод мигал, когда температура ниже НИЖНЕЙ границы, продолжайте гореть, пока температура находится между НИЖНЕЙ ГРАНИЦЕЙ и ВЕРХНЕЙ ГРАНИЦЕЙ, а затем полностью выключите через пять секунд после того, как горшок достигнет ВЕРХНЕЙ границы.

Лично я бы переписал его вот так, как для функциональности, так и для удобства чтения...

int val = 0;                       // analog reading

unsigned const long period = 5000; // time it takes to turn led off at temp

// ---We don't need this till later, zero it so the loop knows not to use it till then
unsigned long startMillis = 0;

void setup() {

    Serial.begin(9600);
    pinMode(led, OUTPUT);
    pinMode(sensor, INPUT);

}

void loop() {

    val = analogRead(sensor);      // temp recorder
    Serial.println(val);

    if ( val <= LOWER_BOUND ) {

        // ---Coffee temp is low, flash the LED
        digitalWrite(led, LOW); 
        delay(200);
        digitalWrite(led, HIGH);
        delay(200);

    } else if ( val < UPPER_BOUND ) {

        // ---Coffee temp is medium, turn the LED solid on (assumes switched cathode)
        digitalWrite(led, LOW); 

    } else {

        // ---Coffee is hot!
        if ( !startMillis ) {

            // ---Coffee just reached UPPER_BOUND... start timing (LED is already on)
            startMillis = millis();

        } else {

            // ---Has the period timed out yet?
            if ( ( millis() - startMillis ) >= period ) {

                  // ---More than 5 seconds has passed, make sure LED is off
                  digitalWrite(led, HIGH);

            }
        }
    }
}

Пара моментов об этой реализации...

1. Я не тестировал этот код на физическом Arduino.
2. Обратите внимание, что мы не собираемся начинать хранение или просмотр millis() до тех пор, пока банк сначала не достигнет UPPER_BOUND. До тех пор все, о чем заботится программа, - это температура кофе.
3. Как и ваш исходный код, эта реализация не учитывает обтекание millis() каждые 50 дней или около того. Маловероятно, что кофейнику потребуется более 50 дней, чтобы достичь целевой температуры, поэтому я бы не беспокоился об этом, но вам следует учитывать эту ситуацию при написании длительных приложений (я отказываюсь называть их "скетчами").
4. Я основал это на вашем исходном коде, так что, как и у вас, как только температура достигает, по крайней мере, нижней границы, она непрерывно записывается на вывод светодиода при каждом проходе через цикл, хотя, вероятно, она не изменилась с последней итерации. Если бы я делал это по-настоящему, я бы перестроил его так, чтобы он записывался на вывод только тогда, когда состояние светодиода действительно меняется. Это всего лишь проблема эффективности, хотя... повторная запись одного и того же значения на пин будет работать нормально, просто это не очень элегантно.
5. Если кофе начинает остывать после достижения ВЕРХНЕЙ ГРАНИЦЫ, то поведение не определено. Я подозреваю, что он будет нормально работать, когда температура кофе низкая или средняя, но если кофе достигнет ВЕРХНЕЙ границы во второй или более раз, я полагаю, что индикатор погаснет немедленно, а не через 5 секунд. Было бы нетрудно улучшить код, чтобы он вел себя правильно, независимо от того, сколько раз температура в кастрюле повышалась и понижалась, но это решение было связано с проблемой, как вы ее описали, которая заключалась в том, что кофейник разогревался только один раз от холодной до целевой температуры.

Во-первых, позвольте мне указать на несколько технических проблем с вашей программой:

1. датчик const int = 9; неверно. В Uno вы можете использовать только analogRead() на выводах с метками от A0 до A5.

2. если (val == ВЕРХНИЙ ПРЕДЕЛ). Никогда не проверяйте аналоговые показания на точное равенство. Чтение шумное, и вы не должны ожидать непрерывности. Он очень хорошо может перейти от UPPER_BOUND-1 при одном показании к UPPER_BOUND+1 при следующем. Вместо этого проверьте значение val >= UPPER_BOUND>.

3. Текущий миллис - начальный миллис == период. Опять же, вы не должны проверять точное равенство. На этот раз по более тонкой причине, связанной с реализацией millis(): некоторые значения (примерно по одному на 42) пропускаются. Здесь снова выполните тест на >= период>.

Существует также проблема, на которую уже указывал PhoenixRevealed, в вашем коде, определяющем два порога, в то время как в вашей прозе упоминается только один. Вполне возможно, что вы просто небрежны и недостаточно точно описываете свои требования.

Далее, и поскольку вы заинтересованы в совершенствовании своего процесса обучения, позвольте мне посоветовать вам два метода, которые стоит изучить, потому что они чрезвычайно полезны в основном для любого проекта Arduino, более сложного , чем просто мигание светодиода:

1. Избегайте использования функции delay(). Пока Arduino занят задержкой, он больше ничего не может сделать. Например, он не может отслеживать изменения температуры на горячей плите. В данном конкретном случае вполне может оказаться, что вам все равно, потому что горячая плита работает так медленно, что вы можете позволить себе опоздать на 400 мс. Но если у вас войдет в привычку полагаться на задержку(), рано или поздно она вас укусит. Поэтому чем раньше вы научитесь мигать светодиодом без использования функции delay(), тем лучше.

2. Научитесь программировать конечную машину. Это концепция программирования, которая очень хорошо подходит для описания реактивных систем, т. е. систем, которые должны реагировать на внешние “события”. Это очень полезная концепция для написания большинства программ, предназначенных для управления оборудованием. Существует довольно много учебных пособий. Я бы рекомендовал Конечный автоматМайенко.

Вот моя интерпретация ваших требований с точки зрения конечного автомата: ваш Arduino может находиться в любом из 3 состояний: ХОЛОДНОЕ (начальное состояние, пластина не достигла требуемой температуры), ОЖИДАНИЕ (пластина достигла температуры, и мы задерживаем пять секунд), ГОТОВО (пять секунд истекли). Правила изменения состояний таковы:

• ХОЛОД → ОЖИДАНИЕ: в ХОЛОДНОМ состоянии, если температура достигает заданного порогового значения, перейдите в состояние ОЖИДАНИЯ.
• ОЖИДАНИЕ → ГОТОВО: когда вы находитесь в состоянии ОЖИДАНИЯ, по истечении пяти секунд с момента входа в состояние, перейдите в состояние ГОТОВО.
• Когда мы находимся в состоянии "ГОТОВО" ... больше ничего никогда не происходит.

Вот соответствующая диаграмма состояния:

Обратите внимание, что как только мы достигаем состояния ГОТОВО, система застревает. Из этой ситуации можно выйти только перезагрузив Arduino. Возможно , вы захотите пересмотреть свою спецификацию, чтобы учесть СДЕЛАННОЕ → ХОЛОДНОЕ переход в некотором роде. Но из вашей спецификации, как написано в вашем вопросе, я предполагаю, что вас устраивает, что система застревает.

Я попытался реализовать эту диаграмму состояний в коде, используя традиционную конструкция переключателя/корпуса. Но потом я обленился и заметил, что звоню exit()-самый простой способ реализации состояния "ГОТОВО", так как эта функция точно предназначена для того, чтобы программа застряла в состоянии "ничего не делать". Затем, поскольку осталось заботиться только о двух состояниях, в качестве переменной состояния можно использовать логическое значение. В конце концов, код, который я предлагаю, может не выглядеть как конечный автомат. Однако важно отметить, что в таком случае конечный автомат является очень полезной концепцией для обдумывания вашей программы и записи ее требований.

// Pinout
const uint8_t LED = 11;
const uint8_t SENSOR = A0;

// Threshold temperature reading.
const int THRESHOLD_TEMP_READING = 220;

// Timing.
const uint32_t LED_TOGGLE_PERIOD = 200;
const uint32_t WAIT_TIME = 5000;

bool is_hot = false;
uint32_t last_led_toggle;
uint32_t wait_started;

void setup()
{
    pinMode(LED, OUTPUT);
    pinMode(SENSOR, INPUT);
}

void loop()
{
    // Read the time once per loop.
    uint32_t now = millis();

    // Toggle the LED state.
    if (now - last_led_toggle >= LED_TOGGLE_PERIOD) {
        digitalWrite(LED, !digitalRead(LED));
        last_led_toggle = now;
    }

    if (is_hot) {
        // If the plate is hot, keep blinking during WAIT_TIME.
        if (millis() - wait_started >= WAIT_TIME) {
            digitalWrite(LED, LOW);  // turn off the LED
            exit(0);                  // stop everything
        }
    } else {
        // If the plate is cold, take note when it gets hot.
        if (analogRead(SENSOR) >= THRESHOLD_TEMP_READING) {
            is_hot = true;
            wait_started = now;
        }
    }
}