Ответ @EdgarBonet кажется очень хорошим решением для пониженного выходного напряжения вывода при использовании резистора низкого номинала.

Вывод Arduino Uno может без проблем выдавать ток 20 мА, а при необходимости даже до 40 мА. Таким образом, безопасным значением для измерения низких значений резистора является 220 Ом, что может привести к максимальному значению 23 мА.

Аналоговый вход A1 используется как цифровой выход для питания схемы, а также как аналоговый вход для измерения падения напряжения.

Это быстрый тест:

// Используем идею из ответа Эдгара Боне
//
// Допустим, что напряжение цифрового выхода
// понижено на минимальное значение резистора,
// для расчета неизвестного резистора.
//
// С двумя резисторами последовательно.
// A1 – 220 Ом – A0 – 10 Ом – GND
//
// Схема представляет собой делитель напряжения.
// A1 питает делитель напряжения.
// A0 измеряет выход.

#define R1 220
#define N_SAMPLES 10

void setup() {
  Serial.begin(9600);
  pinMode(A1,OUTPUT);
  digitalWrite(A1, HIGH);
}

void loop() {

  // Контакт A1 уже настроен как цифровой выход и установлен на ВЫСОКИЙ уровень.
  // Использование AnalogRead(A1) предназначено для измерения реального результата
  // Напряжение. Из-за тока происходит падение напряжения.
  float Vin = averageRead(A1);
  Serial.print("Vin=");
  Serial.print(Vin);

  float Vout = averageRead(A0);
  Serial.print(" Vout=");
  Serial.print(Vout);

  if(Vin > 0.0 && Vout < Vin) {
    float Vt = Vout / Vin;
    float Rx = (Vt * R1) / (1 - Vt);
    Serial.print(" Rx=");
    Serial.println(Rx);
  }

  delay(500);
}

float averageRead(int analogPin) {
  int total = 0;
  for(int i=0; i<N_SAMPLES; i++) {
    total += analogRead(analogPin);
  }
  return float(total) / N_SAMPLES;
}

Это очень приятно. Это не проблема, если неизвестное сопротивление составляет 10 Ом.

Из-за малых номиналов резисторов я не стал добавлять задержки. При высоких значениях резисторов перед измерением аналоговых значений необходима некоторая задержка.

Следующий шаг — найти лучшее значение, найдя значение, которое находится больше всего в середине, как объяснил Эдгар Боне в своем ответе.

// Автоматический выбор диапазона путем нахождения значения, находящегося ближе всего к середине.
// Использование ответа Эдгара Боне

#define N_SAMPLES 10          // количество образцов для усреднения, максимум 30

// Четыре резистора для питания схемы (по одному).
// A1 имеет резистор сопротивлением 220 Ом, A2 — 3 кОм, A3 — 47 кОм и A4 — 750 кОм
// Другая нога резисторов подключена к A0.
// Неизвестный резистор Rx находится на выводе A0 и GND.
const float R[4] = {220.0, 3300.0, 47000.0, 750000.0};
const int pinR[4] = {A1, A2, A3, A4};
const unsigned long wait[4] = {1, 2, 4, 10};  // задержка, значения угаданы.
const int pinMeasure = A0;

void setup() {
  Serial.begin(9600);
  Serial.println("Autoranging");
}

void loop() {
  float Vin[4];    // Vin — это контакт, который питает схему
  float Vout[4];   // Vout — напряжение на неизвестном резисторе

  for(int i=0; i<4; i++) {
    // Питание схемы с помощью этого резистора
    pinMode(pinR[i], OUTPUT);
    digitalWrite(pinR[i], HIGH);

    // Vin — это контакт, который питает схему.
    // Это всегда низкий импеданс, ждать не нужно.
    Vin[i]  = averageRead(pinR[i]);

    // Дополнительная задержка для ожидания стабилизации напряжения,
    // перед чтением аналоговых данных.
    // Может потребоваться для резисторов с наибольшими значениями
    // Возможно, есть кабель к неизвестному резистору
    // у которого есть емкость.
    delay(wait[i]);

    // Первый «analogread()» устанавливает мультиплексор.
    // Для цепи с высоким импедансом первый
    // Analogread() может быть менее точным.
    // Прочитайте его несколько раз и выбросьте.
    averageRead(pinMeasure);

    // К настоящему моменту все решено.
    // Чтение аналогового ввода по-настоящему.
    Vout[i] = averageRead(pinMeasure);

    pinMode(pinR[i], INPUT);  // Делаем этот вывод высоким импедансом
  }

  // Найдите значение Vout, которое находится больше всего в середине.
  // Для Arduino Uno среднее значение АЦП равно 512.
  float diff = 2000.0; // устанавливаем значение выше возможного по умолчанию
  int best = 0;        // индекс лучшего резистора

  for(int i=0; i<4; i++) {
    float d = fabs(512.0 - Vout[i]); // разница для этого резистора
    if(d < diff) {                   // ближе к середине?
      diff = d;                      // запоминаем новую разницу
      best = i;                      // запоминаем индекс лучшего резистора
    }
  }

  if(Vin[best] <= 0.0) {
    Serial.println("Something wrong with the circuit");
  }
  else if(Vout[best] >= Vin[best]) {
    Serial.println("Rx not connected");
  }
  else {
    float Vt = Vout[best] / Vin[best];     // временный предварительный расчет
    float Rx = (Vt * R[best]) / (1 - Vt);  // вычисляем неизвестный резистор

    Serial.print(" Rx=");
    Serial.print(Rx);
    Serial.print(" ohm (with resistor ");
    Serial.print(R[best]);
    Serial.print(")");
    Serial.println();
  }

  delay(250);
}

float averageRead(int analogPin) {
  int total = 0;
  for(int i=0; i<N_SAMPLES; i++) {
    total += analogRead(analogPin);
  }
  total += N_SAMPLES / 2;  // см. www.gammon.com.au/adc
  return(float(total) / float(N_SAMPLES));
}

Я хотел бы добавить конденсатор от A0 к GND (параллельно неизвестному резистору), чтобы уменьшить шум. Этот конденсатор должен быть 1 нФ или меньше. Задержка в коде достаточно велика, чтобы дождаться стабилизации напряжения до 1 нФ.

Увеличение резисторов в 15 раз — большой шаг. Это делает его менее точным, но у Arduino Uno всего 6 аналоговых входов. Лучше использовать 5 резисторов с увеличением в 6 раз.
4 резистора 15х: 220, 3к3, 47к, 750к
5 резисторов 6х: 220, 1к2, 8к2, 47к, 270к

Есть несколько способов добиться большего:

• Когда два резистора дают выходной сигнал, близкий к среднему, можно усреднить результаты.
• При использовании 5 резисторов можно, например, уменьшить номинал резистора 8 к2. Когда включены все более высокие значения, результирующее значение резистора становится 6к8 вместо 8к2.
• При высоких значениях резисторов выходное напряжение контакта не снижается, и также можно использовать цифровые выходы.

Может потребоваться защитный резистор для A0. Я думаю, что значение 470 Ом или 1 кОм должно подойти.

Большое спасибо @EdgarBonet, я использовал его ответ и добавил среднее значение и задержку.

Обновление, ноябрь 2018 г.

@RekaiaDraoui

При использовании макетной платы могут быть не идеальные контакты. Это может вызвать массу неприятностей.

Используете ли вы такую схему: