установка выходного аналогового/цифрового контакта на землю

Question

установка выходного аналогового/цифрового контакта на землю

arduino-nano analogwrite digitalwrite

Итак, мне нужно автоматически извлечь CD из привода Blu-Ray, у меня есть провод, приваренный к карте привода, который, если вручную подключить на долю секунды (импульс) к земле той же карты на приводе, извлечет CD. Теперь, чтобы сделать это автоматически, я использую Arduino Nano и подключил этот провод к аналоговому выводу "d1", установил его режим на Output и соединил земли Arduino и привода вместе. Вот мой код 1

int ds1 = A2; //контакт, который указывает на наличие компакт-диска внутри привода, если HIGH, и на его отсутствие в противном случае
int d1 = A3;  //контакт, подключенный к проводу, который при подключении к земле выталкивает компакт-диск

void setup() {
  Serial.begin(9600);
  pinMode(ds1, INPUT);
  pinMode(d1, OUTPUT);
  while((!analogRead(ds1))) //если CD нет в приводе, ждем
  {}
}

void loop() {
  analogWrite(d1,0); //извлечь CD
  delay(500);
  while(!analogRead(ds1)) //если CD нет в приводе, ждем
  {}
  delay(1000);
}

Я думаю, что, возможно, установка пина на 0 не обязательно означает, что я подключил его к земле, это просто возможность. Если вы видите что-то неправильное в коде или у вас есть какие-либо предложения, пожалуйста, помогите мне

@SalmaG, 👍0

Обсуждение

https://majko.co.uk/blog/what-exactly-gpio-pin, @Majenko

pinMode(d1, OUTPUT); устанавливает контакт LOW (0 ноль), подключенный к земле, @Juraj

while(!digitalRead(ds1)) лучше разместить в первой строке цикла. Тогда вы можете исключить его из setup(), @Juraj

что вы подразумеваете под приводом Blu-Ray? ... это привод на компьютере или проигрыватель Blu-Ray?, @jsotola

проигрыватель Blu-ray, не подключенный к компьютеру, @SalmaG

1 ответ

Лучший ответ:

@*Majenko* · Accepted Answer · 2018-08-23 12:06-00:00

Да, установка вывода в положение ВЫХОД и установка его в положение НИЗКИЙ фактически подключает вывод к земле (через сопротивление в несколько Ом).

Однако в вашем коде есть несколько ошибок, на которые следует обратить внимание:

Используйте digitalWrite(), а не AnalogWrite().

analogWrite(pin, 0) фактически то же самое, что и digitalWrite(pin, 0), но это неоднозначно для того, кто читает ваш код.

Вы никогда не "отпускаете" вывод, поэтому как только он становится НИЗКИМ, он остается НИЗКИМ. Вам следует эмулировать открытый сток, установив его на ВХОД, когда он не используется.
Вам следует выработать привычку помещать повторяющийся код в функции, чтобы сделать происходящее более понятным.

Например:

void setup() {
  Serial.begin(9600);
  pinMode(ds1, INPUT);
  pinMode(d1, INPUT);
  waitForCD();
}

void loop() {
  triggerEject();
  waitForCD();
  delay(1000);
}

void triggerEject() {
  pinMode(d1, OUTPUT);
  digitalWrite(d1, LOW); // Нажимаем кнопку
  delay(100); // Это то, как долго кнопка будет нажата
  pinMode(d1, INPUT); // Отпускаем кнопку
}

void waitForCD() {
  while(!analogRead(ds1)) //если CD нет в приводе, ждем
  {}
}

!analogRead(ds1) будет истинным только в том случае, если напряжение на выводе A2 равно нулю вольт. Если вы действительно хотите прочитать аналоговое напряжение здесь, вам следует найти пороговое значение, с которым сравнивается значение:

пока (analogRead(ds1) < 100)) {}

Или, возможно, вы на самом деле хотите использовать digitalRead()...