Код датчика температуры LMT01 не работает - нужна помощь

6 апреля 2018 г., 21:52

Надеюсь, это уместно. Я разместил этот вопрос на сайте Arduino/Sensor, получил 42 просмотра, но не получил ответа.

Мне не удалось получить помощь ни в одной из предыдущих публикаций на эту тему, поэтому я начинаю с нового кода Кевана Дарра. Он хороший программист, поэтому код должен работать, но не работает. Я много читал и понимаю, как это должно работать, поэтому позвольте мне потратить несколько слов на объяснение того, что я узнал, и, возможно, кто-то сможет взять это оттуда. Выход LMT01 составляет импульсы от 0,6 В до 1,6 В шириной 10 мкс, я проверил это с помощью осциллографа, общее количество этих импульсов пропорционально температуре. Это повторяется каждые 100 мс. Этот сигнал подается на контакт D2, но это цифровой контакт: High = 5V, Low = 0V, но Arduino IDE делает что-то скрытое, когда вы используете специальную функцию «attachInterrupt (pin, ISR, Falling)» — она перенаправляет сигнал внутри к контакту A0N положительной стороны аналогового компаратора и подключает к AN1 внутри стабильное опорное напряжение 1,1 В. Теперь импульсы от 0,6 В до 1,6 В точно центрируются на компараторе, поэтому он выдает идеальные единицы и нули для легкого подсчета.

Итак, повторюсь, только Pin2 подключен с помощью LMT01 к Arduino. Почему не работает эта &!#^-штука, правильно скомпилировалась и загрузилась. Если бы у меня был отладчик этого софта, перемещая по одной строке за раз, я мог бы исправить это сам. Далее следует код:

 //Пример кода для датчика температуры LMT01
//LMT01ELPGQ1
//Кевин Дарра

//Временные контакты
#define pulsePin 2 //D2 на arduino D5 на esp8266 **Это вывод LMT01

//глобальные значения для датчика температуры LMT01
volatile unsigned int pulseCount = 0;//импульсы из датчика
float temperatureC = 0, temperatureF = 0;//преобразованные температуры
float tempHIGH, tempLOW = 1000;

//функции
void pulseDetect();//функция прерывания
float getTemperature();//вызываем это, чтобы получить температуру от LMT01 - возвращает значение с плавающей запятой для температуры в (C)

void setup() {
  Serial.begin(115200);
  pinMode(pulsePin, INPUT);//выход из цепи датчика LMT01

}

void loop() {
  temperatureC = getTemperature();// вызовите getTemperature(), чтобы вернуть температуру в C
  if (temperatureC != 1000) {// возвращает 1000, если что-то пошло не так
    temperatureF = temperatureC * 9.000 / 5.000 + 32;
    if (temperatureF > tempHIGH)
      tempHIGH = temperatureF;
    if (temperatureF < tempLOW)
      tempLOW = temperatureF;
    Serial.print(temperatureC);
    Serial.print("C  ");
    Serial.print(temperatureF);
    Serial.print("F  HIGH=");
    Serial.print(tempHIGH);
    Serial.print("F  LOW=");
    Serial.print(tempLOW);
    Serial.print("F  DIFF=");
    Serial.print(tempHIGH - tempLOW);
    Serial.print("F  ");
    Serial.print(pulseCount);
    Serial.println("pulses  ");
    for (int i = 0; i < random(50, 200); i++)
      delay(1);
  }

}




float getTemperature() {// ********** GET TEMPERATURE FUNCTION *** возвращает температуру C
  attachInterrupt(digitalPinToInterrupt(pulsePin), pulseDetect, FALLING);//используем триггер tp вывода прерывания по заднему фронту

  unsigned long conversionStartTime = millis();//отслеживает время

  while (millis() - conversionStartTime < 10) { // ищем тишину, на случай, если мы перейдем к считыванию температуры в середине измерения, дождемся следующего
   // yield();//для ESP8266, чтобы другие задачи были довольны
    if (pulseCount > 0) {
      pulseCount = 0;
      conversionStartTime = millis();
    }
  }

  pulseCount = 0;//сброс счетчика импульсов
  while (millis() - conversionStartTime < 150) {//ожидание первого импульса
   // yield(); // чтобы ESP8266 выполнял другие задачи
    if (pulseCount > 0)
      break;
  }
  if (pulseCount == 0)
    return 1000;//FAIL - никогда не было импульса

  conversionStartTime = millis();//конвертация выполнена, поэтому сбрасываем время
  unsigned int oldPulseCount = pulseCount;//просто для того, чтобы отслеживать тайминги, когда пин пульса бездействует
  unsigned long pulseTime = millis();
  while (millis() - conversionStartTime < 60) { // измеряем импульсы
   // yield(); // чтобы ESP8266 выполнял другие задачи

    if (pulseCount != oldPulseCount) {//новый пульс, поэтому обновите таймер
      oldPulseCount = pulseCount;
      pulseTime = millis();
    }
    else if (millis() - pulseTime > 5) {// какое-то время импульсов не будет, необходимо выполнить.
      break;
    }
  }
  //^^^ Застревает здесь, считая импульсы в течение 60 мс

  if (pulseCount < 5) { //это просто шум, ложный срабатывание... Я имею в виду только 5 импульсов, это не может быть правдой
    return 1000;//НЕУДАЧА
  }

  detachInterrupt(digitalPinToInterrupt(pulsePin));//готово с прерыванием
  temperatureC = 256.000 * pulseCount / 4096.000 - 50;//преобразование
  //см. 7.3.2 Выходная передаточная функция в таблице данных

  return temperatureC;//сбрасываем температуру обратно
}

// изменить эту функцию, чтобы она выглядела так, если используется ESP8266
//аннулировать ICACHE_RAM_ATTR pulseDetect()

void pulseDetect() {// ********** ФУНКЦИЯ ПРЕРЫВАНИЯ СЧЕТЧИКА ИМПУЛЬСОВ
  pulseCount++;
}