LCD дисплей не показывает

Первое, что вам нужно сделать, это запустить примеры из библиотеки. Если это не сработает, проверьте свои соединения и компоненты.

Если пример работает, то это должен быть ваш скетч (проблема программирования).

Хорошая практика: пишите короткие скетчи, которые проверяют только один компонент вашего проекта. Пример: в вашем проекте используются ЖК-дисплей, датчик температуры и кнопка, вы написали три коротких теста. Если что-то пойдет не так с вашим проектом, вы можете использовать тестовые скетчи, чтобы определить, в чем проблема

Я согласен с Look Alterno по поводу инициализации ЖК-дисплея. Загрузите этот простой скетч, а затем попробуйте настроить потенциометр 10k ohm на задней панели печатной платы I2C, пока не увидите текст.

#include <Wire.h> 
#include <LiquidCrystal_I2C.h>

const byte LCDcolumns = 16;
const byte LCDrows = 2;

// 0x27 - это адрес по умолчанию. Ваш адрес 0x3F - если да, измените 0x27 на 0x3F
LiquidCrystal_I2C lcd(0x27, LCDcolumns, LCDrows);

void setup(){
  lcd.init();
  lcd.backlight();
  lcd.home();
  lcd.print("16 x 2 LCD Test");
}

void loop(){

}

Там могут быть разные версии библиотеки LiquidCrystal_I2C. Пример "HelloWorld", поставляемый с моей библиотекой, имеет следующие комментарии в верхней части скетча:

//YWROBOT
//Compatible with the Arduino IDE 1.0
//Library version:1.1

Вы можете изменить адрес I2C в этом скетче на 0x3F и повторить попытку.

Потенциометр, который нуждается в регулировке, находится на вашей плате I2C, показанной здесь красной стрелкой, указывающей на него:

черные полосы указывают на то, что ЖК-дисплей неправильно инициализирован.

проверьте оборудование / соединение и убедитесь, что ваше программное обеспечение инициализирует его правильно.

Ну, у меня есть оборудование, поэтому я проверил конфигурацию OP. У меня это тоже не сработало. Та же самая проблема операции.

Причина-адрес I2C, который мы используем (0x27). Это не мой ЖК-адрес, и, вероятно, не ваш адрес. В моем случае это 0x3F.

Я обнаружил это I2CScanner, короткий скетч, в котором перечислены все устройства I2C, подключенные в тот момент. Итак, запустите его (с подключенным ЖК-дисплеем) и следите с помощью последовательного монитора за адресом вашего ЖК-дисплея.

Затем замените все ссылки на 0x27 (например, lcd(0x27, 16, 2)) вашим реальным адресом. Просто измените одно значение на другое.

Это I2CScanner

//
// Версия 1
// Эта программа (или код, похожий на нее)
// можно найти во многих местах.
// Например, на Arduino.cc форум.
// Оригинального автора не знаю.
// Версия 2, Juni 2012, Использование Arduino 1.0.1
// Адаптировано так, чтобы быть как можно более простым с помощью Arduino.cc пользователь Krodal
// Версия 3, 26 февраля 2013 г.
// V3 by louarnold
// Версия 4, 3 марта 2013 года, с использованием Arduino 1.0.3
// по Arduino.cc пользователь Krodal.
// Изменения луарнольда удалены.
// Адреса сканирования изменены с 0...127 на 1...119,
// по данным сканера i2c Ника Гэммона
// http://www.gammon.com.au/forum/?id=10896
// Версия 5, 28 марта 2013 г.
// Как версия 4, но адрес теперь сканируется до 127.
// Датчик, похоже, использует адрес 120.
// Версия 6, 27 ноября 2015 года.
// Добавлено ожидание последовательной связи Leonardo.
// 
//
// Этот скетч тестирует стандартные 7-битные адреса
// Устройства с более высоким битовым адресом могут быть видны неправильно.
//

#include <Wire.h>


void setup()
{
  Wire.begin();

  Serial.begin(9600);
  while (!Serial);             // Леонардо: дождитесь последовательного монитора
  Serial.println("\nI2C Scanner");
}


void loop()
{
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ ) 
  {
    // i2c_scanner использует возвращаемое значение
    // Write.endTransmission, чтобы увидеть
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4) 
    {
      Serial.print("Unknown error at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000);           // подождите 5 секунд для следующего сканирования
}