Получение BPM из данного кода

Если вы знаете интервал между ударами сердца, вы можете рассчитать частоту по формуле: частота = 1 / время. Теперь, если вы возьмете частоту и умножите ее на 60, то получите BPM.

У меня нет одного из датчиков, которые вы используете, поэтому я подключил потенциометр к контакту A0, чтобы проверить этот код.

    int UpperThreshold = 518;
    int LowerThreshold = 490;
    int reading = 0;
    float BPM = 0.0;
    bool IgnoreReading = false;
    bool FirstPulseDetected = false;
    unsigned long FirstPulseTime = 0;
    unsigned long SecondPulseTime = 0;
    unsigned long PulseInterval = 0;

    void setup(){
      Serial.begin(9600);
    }

    void loop(){

      reading = analogRead(0); 

      // Обнаружен передний край сердечного ритма.
      if(reading > UpperThreshold && IgnoreReading == false){
        if(FirstPulseDetected == false){
          FirstPulseTime = millis();
          FirstPulseDetected = true;
        }
        else{
          SecondPulseTime = millis();
          PulseInterval = SecondPulseTime - FirstPulseTime;
          FirstPulseTime = SecondPulseTime;
        }
        IgnoreReading = true;
      }

      // Обнаружена задняя кромка сердечного ритма.
      if(reading < LowerThreshold){
        IgnoreReading = false;
      }  

      BPM = (1.0/PulseInterval) * 60.0 * 1000;

      Serial.print(reading);
      Serial.print("\t");
      Serial.print(PulseInterval);
      Serial.print("\t");
      Serial.print(BPM);
      Serial.println(" BPM");
      Serial.flush();

      // Пожалуйста, не используйте delay() - это только для целей тестирования.
      delay(50);  
    }

Обновленный ответ в ответ на ваши комментарии ниже:

Скетч считывает данные и отправляет их на последовательный монитор каждые 50 мс из-за задержки(50). Что, если мы изменим это на 1000 мс? Последовательный монитор будет обновляться один раз в секунду, что будет более "удобочитаемым". Проблема с этой идеей заключается в том, что при частоте сердечных сокращений выше 60 ударов в минуту показания будут неточными. У меня нет датчика для тестирования, но я предполагаю, что задержка в 1 секунду сделает код неработоспособным.

Прежде чем мы добавим больше сложности к этому скетчу, мы действительно должны избавиться от этой задержки. Было бы неплохо иметь один "таймер", который мы могли бы использовать для обновления расчета BPM, и второй "таймер" для обновления последовательного монитора каждую секунду, или полсекунды, или что бы вы ни хотели.

Мы можем сделать это без каких-либо библиотек, используя millis(). Вот обновленный скетч с использованием millis() для таймеров. К этому скетчу добавлено мигание бортового светодиода. Я использую Uno, так что вам придется изменить LED_BUILDIN на любой контакт, который вы используете.

int UpperThreshold = 518;
int LowerThreshold = 490;
int reading = 0;
float BPM = 0.0;
bool IgnoreReading = false;
bool FirstPulseDetected = false;
unsigned long FirstPulseTime = 0;
unsigned long SecondPulseTime = 0;
unsigned long PulseInterval = 0;
const unsigned long delayTime = 10;
const unsigned long delayTime2 = 1000;
const unsigned long baudRate = 9600;
unsigned long previousMillis = 0;
unsigned long previousMillis2 = 0;

void setup(){
  Serial.begin(baudRate);
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LOW);
}

void loop(){

  // Получить текущее время
  unsigned long currentMillis = millis();

  // Первое событие
  if(myTimer1(delayTime, currentMillis) == 1){

    reading = analogRead(0); 

    // Обнаружен передний край сердечного ритма.
    if(reading > UpperThreshold && IgnoreReading == false){
      if(FirstPulseDetected == false){
        FirstPulseTime = millis();
        FirstPulseDetected = true;
      }
      else{
        SecondPulseTime = millis();
        PulseInterval = SecondPulseTime - FirstPulseTime;
        FirstPulseTime = SecondPulseTime;
      }
      IgnoreReading = true;
      digitalWrite(LED_BUILTIN, HIGH);
    }

    // Обнаружена задняя кромка сердечного ритма.
    if(reading < LowerThreshold && IgnoreReading == true){
      IgnoreReading = false;
      digitalWrite(LED_BUILTIN, LOW);
    }  

    // Рассчитать удары в минуту.
    BPM = (1.0/PulseInterval) * 60.0 * 1000;
  }

  // Второе событие
  if(myTimer2(delayTime2, currentMillis) == 1){
    Serial.print(reading);
    Serial.print("\t");
    Serial.print(PulseInterval);
    Serial.print("\t");
    Serial.print(BPM);
    Serial.println(" BPM");
    Serial.flush();
  }
}

// First event timer
int myTimer1(long delayTime, long currentMillis){
  if(currentMillis - previousMillis >= delayTime){previousMillis = currentMillis;return 1;}
  else{return 0;}
}

// Second event timer
int myTimer2(long delayTime2, long currentMillis){
  if(currentMillis - previousMillis2 >= delayTime2){previousMillis2 = currentMillis;return 1;}
  else{return 0;}
}

Размер компиляции кода с задержкой составляет 4732 против таймеров millis на уровне 4682 (с удаленным светодиодным кодом). Два таймера дешевле цены одной задержки :)

Светодиод будет гореть в течение всего времени, пока показания сердечного ритма будут находиться выше нижнего порога. Если вы хотите, чтобы он был включен дольше или решите, как долго он должен быть включен, я не буду писать код для вас, но дам вам подсказку. Вы можете снова скопировать myTimer1() и сделать третий таймер.