FlySky TH9X с Arduino: невозможно заставить функциюpulsIn() возвращать разумные значения для любого канала

Я бы не рекомендовал использовать pulseIn для считывания значений с приемника. pulseIn блокирует программу до тех пор, пока не будет получен сигнал, что почти всегда нежелательно.

Альтернативным подходом было бы использование прерываний CHANGE. Вы получаете прерывание, когда сигнал становится высоким и низким. Вы отмечаете время, когда происходит каждое изменение, с помощью millis и сравниваете время, чтобы получить длительность сигнала.

Вот пример — вы можете добавить больше каналов, если хотите. Обратите внимание, что здесь используется библиотека EnableInterrupt.

#include <EnableInterrupt.h>

#define SERIAL_PORT_SPEED 57600
#define RC_NUM_CHANNELS  2

#define RC_CH1  0
#define RC_CH2  1
#define RC_CH1_INPUT  A0
#define RC_CH2_INPUT  A1   

uint32_t last_update_time = 0;
uint16_t rc_values[RC_NUM_CHANNELS];
uint32_t rc_start[RC_NUM_CHANNELS];
volatile uint16_t rc_shared[RC_NUM_CHANNELS];

void rc_read_values() {
  // считываем значения из общего, изменчивого массива (который может измениться в любое время)
  // и в массив, который мы изменим только при вызове этой функции

  noInterrupts();
  memcpy(rc_values, (const void *)rc_shared, sizeof(rc_shared));
  interrupts();
}

void calc_input(uint8_t channel, uint8_t input_pin) {
  // Это прерывание. Если вывод высокий, мы записываем начало
  // время импульса. Если пин низкий, мы сравниваем время начала
  // к текущему времени, чтобы получить длину импульса.

  if (digitalRead(input_pin) == HIGH) {
    rc_start[channel] = micros();
  } else {
    uint16_t rc_compare = (uint16_t)(micros() - rc_start[channel]);
    rc_shared[channel] = rc_compare;
  }
}

void calc_ch1() { calc_input(RC_CH1, RC_CH1_INPUT); }
void calc_ch2() { calc_input(RC_CH2, RC_CH2_INPUT); }  

void setup() {
  Serial.begin(SERIAL_PORT_SPEED);

  pinMode(RC_CH1_INPUT, INPUT);
  pinMode(RC_CH2_INPUT, INPUT);

  // настраиваем прерывания CHANGE, чтобы получать уведомления, когда
  // каждый сигнал становится высоким или низким.
  enableInterrupt(RC_CH1_INPUT, calc_ch1, CHANGE);
  enableInterrupt(RC_CH2_INPUT, calc_ch2, CHANGE);
}

void loop() {
  rc_read_values();

  Serial.print("CH1:"); Serial.println(rc_values[RC_CH1]);
  Serial.print("CH2:"); Serial.println(rc_values[RC_CH2]);

  delay(200);  // просто чтобы последовательный журнал не переполнялся
}

Более подробное объяснение можно найти здесь: http://rcarduino.blogspot.com/2012/01/how-to-read-rc-receiver-with.html

Используйте большее время ожидания (30000):

int rcPin1 = 3; // ШИМ-сигнал arduino pin
int rcPin2 = 4; // ШИМ-сигнал arduino pin
int rcPin3 = 5; // ШИМ-сигнал arduino pin
int rcPin4 = 6; // ШИМ-сигнал arduino pin
int rcPin5 = 7; // ШИМ-сигнал arduino pin
int rcPin6 = 8; // ШИМ-сигнал arduino pin
int ch1 = 0;    // Значение ШИМ канала 1 приемника
int ch2 = 0;    // Значение ШИМ приемника 1
int ch3 = 0;    // Значение ШИМ приемника 1
int ch4 = 0;    // Значение ШИМ канала 1 приемника
int ch5 = 0;    // Значение ШИМ канала 1 приемника
int ch6 = 0;    // Значение ШИМ приемника 1
void setup() {
  pinMode(rcPin1, INPUT);
  pinMode(rcPin2, INPUT);
  pinMode(rcPin3, INPUT);
  pinMode(rcPin4, INPUT);
  pinMode(rcPin5, INPUT);
  pinMode(rcPin6, INPUT);
  Serial.begin(9600);
}

void loop() {
  // Считываем длину сигнала в микросекундах
  ch1 = pulseIn(rcPin1, HIGH, 30000);
  Serial.print("Channel #1: ");
  Serial.println(ch1);
  ch2 = pulseIn(rcPin2, HIGH, 30000);
  Serial.print("Channel #2: ");
  Serial.println(ch2);
  ch3 = pulseIn(rcPin3, HIGH, 30000);
  Serial.print("Channel #3: ");
  Serial.println(ch3);
  ch4 = pulseIn(rcPin4, HIGH, 30000);
  Serial.print("Channel #4: ");
  Serial.println(ch4);
 ch5 = pulseIn(rcPin5, HIGH, 30000);
  Serial.print("Channel #5: ");
  Serial.println(ch5);
  ch6 = pulseIn(rcPin6, HIGH, 30000);
  Serial.print("Channel #6: ");
  Serial.println(ch6);
 delay(1000);
}